aboutsummaryrefslogtreecommitdiffstats
path: root/src/qmltest/qmltest.pro
blob: 9ed792748cf2ff606b2e2df4dd36da5c09d54ed9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
TARGET     = QtQuickTest

DEFINES += QT_NO_URL_CAST_FROM_STRING
QT = core
QT_PRIVATE = testlib-private quick qml-private v8-private gui core-private

!contains(QT_CONFIG, no-widgets) {
    QT += widgets
    DEFINES += QT_QMLTEST_WITH_WIDGETS
}

load(qt_module)

# Install qmltestcase.prf into the Qt mkspecs so that "CONFIG += qmltestcase"
# can be used in customer applications to build against QtQuickTest.
feature.path = $$[QT_INSTALL_DATA]/mkspecs/features
feature.files = $$PWD/features/qmltestcase.prf
INSTALLS += feature

SOURCES += \
    $$PWD/quicktest.cpp \
    $$PWD/quicktestevent.cpp \
    $$PWD/quicktestresult.cpp
HEADERS += \
    $$PWD/quicktestglobal.h \
    $$PWD/quicktest.h \
    $$PWD/quicktestevent_p.h \
    $$PWD/quicktestresult_p.h \
    $$PWD/qtestoptions_p.h

DEFINES += QT_QML_DEBUG_NO_WARNING