blob: 2f2644870736e3fc495894fec46fe3de494b617e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
TARGET = QtQuickTest
QMAKE_DOCS = $$PWD/doc/qtqmltest.qdocconf
DEFINES += QT_NO_URL_CAST_FROM_STRING QT_NO_FOREACH
QT = core testlib-private
QT_PRIVATE = quick quick-private qml-private gui core-private
# Testlib is only a private dependency, which results in our users not
# inheriting testlibs's MODULE_CONFIG transitively. Make it explicit.
MODULE_CONFIG += $${QT.testlib.CONFIG}
qtHaveModule(widgets) {
QT += widgets
DEFINES += QT_QMLTEST_WITH_WIDGETS
}
SOURCES += \
$$PWD/quicktest.cpp \
$$PWD/quicktestresult.cpp
HEADERS += \
$$PWD/quicktestglobal.h \
$$PWD/quicktest.h \
$$PWD/quicktest_p.h \
$$PWD/quicktestresult_p.h \
$$PWD/qtestoptions_p.h
qtConfig(qml-debug): DEFINES += QT_QML_DEBUG_NO_WARNING
load(qt_module)
QMLTYPES_FILENAME = plugins.qmltypes
QMLTYPES_INSTALL_DIR = $$[QT_INSTALL_QML]/QtTest
QML_IMPORT_NAME = QtTest
QML_IMPORT_VERSION = $$QT_VERSION
CONFIG += qmltypes install_qmltypes install_metatypes
|