blob: 1e2c0360c2b7d61ca93c5708d74b475b55be1224 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
TARGET = QtQuick
QT = core-private gui-private qml-private qmlmodels-private
qtConfig(qml-network): \
QT_PRIVATE += network
### To support compatibility API that is only available when using RHI/OpenGL
qtConfig(opengl) {
QT_PRIVATE += opengl-private
QT += opengl
}
TRACEPOINT_PROVIDER = $$PWD/qtquick.tracepoints
CONFIG += qt_tracepoints
DEFINES += QT_NO_URL_CAST_FROM_STRING QT_NO_INTEGER_EVENT_COORDINATES
msvc:DEFINES *= _CRT_SECURE_NO_WARNINGS
solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2
win32: LIBS += -luser32
DEFINES += QT_NO_FOREACH
exists("qqml_enable_gcov") {
QMAKE_CXXFLAGS = -fprofile-arcs -ftest-coverage -fno-elide-constructors
LIBS_PRIVATE += -lgcov
}
QMAKE_DOCS = $$PWD/doc/qtquick.qdocconf
MODULE_PLUGIN_TYPES += \
scenegraph
ANDROID_BUNDLED_FILES += \
qml
include(util/util.pri)
include(scenegraph/scenegraph.pri)
include(items/items.pri)
include(handlers/handlers.pri)
qtConfig(quick-designer): \
include(designer/designer.pri)
qtConfig(accessibility) {
include(accessible/accessible.pri)
}
HEADERS += \
qtquickglobal.h \
qtquickglobal_p.h
# To make #include "qquickcontext2d_jsclass.cpp" work
INCLUDEPATH += $$PWD
load(qt_module)
QMLTYPES_FILENAME = plugins.qmltypes
QMLTYPES_INSTALL_DIR = $$[QT_INSTALL_QML]/QtQuick
QML_IMPORT_NAME = QtQuick
QML_IMPORT_VERSION = $$QT_VERSION
CONFIG += qmltypes install_qmltypes install_metatypes
# Install QtQuick.Window qmldir
qmldir.files = $$PWD/../imports/window/qmldir
qmldir.path = $$[QT_INSTALL_QML]/QtQuick/Window
prefix_build: INSTALLS += qmldir
else: COPIES += qmldir
|