blob: d4e66be413e6cb0dfdfe6834d8e772b1db715020 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
TEMPLATE = subdirs
CONFIG += ordered
include($$OUT_PWD/qml/qtqml-config.pri)
include($$OUT_PWD/quick/qtquick-config.pri)
QT_FOR_CONFIG += qml qml-private quick-private
# We need qmltyperegistrar for all type registrations, even in qml
SUBDIRS += \
qmltyperegistrar \
qml \
qmlmodels
qtConfig(qml-worker-script): \
SUBDIRS += qmlworkerscript
qtHaveModule(gui):qtConfig(qml-animation) {
SUBDIRS += quick
qtConfig(quick-path): \
SUBDIRS += quickshapes
qtConfig(testlib): \
SUBDIRS += qmltest
qtConfig(quick-particles): \
SUBDIRS += particles
qtHaveModule(widgets): SUBDIRS += quickwidgets
qtConfig(private_tests):qtConfig(testlib) {
src_qmltest_doc_snippets.subdir = qmltest/doc/snippets
src_qmltest_doc_snippets.target = sub-qmltest-doc-snippets
src_qmltest_doc_snippets.depends = src_qmltest
SUBDIRS += src_qmltest_doc_snippets
}
}
SUBDIRS += \
plugins \
imports
qtConfig(qml-devtools) {
SUBDIRS += \
qmldevtools \
qmlcompiler
qmldevtools.depends = qml
qmlcompiler.depends = qmldevtools
}
qtConfig(qml-network) {
QT_FOR_CONFIG += network
qtConfig(thread):qtConfig(localserver):qtConfig(qml-debug): SUBDIRS += qmldebug
}
DISTFILES += sync.profile configure.json
|