1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtTest
import QtQuick.Controls
TestCase {
id: testCase
width: 200
height: 200
visible: true
when: windowShown
name: "ItemDelegate"
Component {
id: itemDelegate
ItemDelegate { }
}
function test_defaults() {
failOnWarning(/.?/)
let control = createTemporaryObject(itemDelegate, testCase)
verify(control)
}
function test_baseline() {
var control = createTemporaryObject(itemDelegate, testCase)
verify(control)
compare(control.baselineOffset, control.contentItem.y + control.contentItem.baselineOffset)
}
function test_highlighted() {
var control = createTemporaryObject(itemDelegate, testCase)
verify(control)
verify(!control.highlighted)
control.highlighted = true
verify(control.highlighted)
}
function test_spacing() {
var control = createTemporaryObject(itemDelegate, testCase, { text: "Some long, long, long text" })
verify(control)
verify(control.contentItem.implicitWidth + control.leftPadding + control.rightPadding > control.background.implicitWidth)
var textLabel = findChild(control.contentItem, "label")
verify(textLabel)
// The implicitWidth of the IconLabel that all buttons use as their contentItem
// should be equal to the implicitWidth of the Text while no icon is set.
compare(control.contentItem.implicitWidth, textLabel.implicitWidth)
// That means that spacing shouldn't affect it.
control.spacing += 100
compare(control.contentItem.implicitWidth, textLabel.implicitWidth)
// The implicitWidth of the ItemDelegate itself should, therefore, also never include spacing while no icon is set.
compare(control.implicitWidth, textLabel.implicitWidth + control.leftPadding + control.rightPadding)
}
function test_display_data() {
return [
{ "tag": "IconOnly", display: ItemDelegate.IconOnly },
{ "tag": "TextOnly", display: ItemDelegate.TextOnly },
{ "tag": "TextUnderIcon", display: ItemDelegate.TextUnderIcon },
{ "tag": "TextBesideIcon", display: ItemDelegate.TextBesideIcon },
{ "tag": "IconOnly, mirrored", display: ItemDelegate.IconOnly, mirrored: true },
{ "tag": "TextOnly, mirrored", display: ItemDelegate.TextOnly, mirrored: true },
{ "tag": "TextUnderIcon, mirrored", display: ItemDelegate.TextUnderIcon, mirrored: true },
{ "tag": "TextBesideIcon, mirrored", display: ItemDelegate.TextBesideIcon, mirrored: true }
]
}
function test_display(data) {
var control = createTemporaryObject(itemDelegate, testCase, {
text: "ItemDelegate",
display: data.display,
width: 400,
"icon.source": "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/check.png",
"LayoutMirroring.enabled": !!data.mirrored
})
verify(control)
compare(control.icon.source, "qrc:/qt-project.org/imports/QtQuick/Controls/Basic/images/check.png")
var iconImage = findChild(control.contentItem, "image")
var textLabel = findChild(control.contentItem, "label")
switch (control.display) {
case ItemDelegate.IconOnly:
verify(iconImage)
verify(!textLabel)
compare(iconImage.x, (control.availableWidth - iconImage.width) / 2)
compare(iconImage.y, (control.availableHeight - iconImage.height) / 2)
break;
case ItemDelegate.TextOnly:
verify(!iconImage)
verify(textLabel)
compare(textLabel.x, control.mirrored ? control.availableWidth - textLabel.width : 0)
compare(textLabel.y, (control.availableHeight - textLabel.height) / 2)
break;
case ItemDelegate.TextUnderIcon:
verify(iconImage)
verify(textLabel)
compare(iconImage.x, (control.availableWidth - iconImage.width) / 2)
compare(textLabel.x, (control.availableWidth - textLabel.width) / 2)
verify(iconImage.y < textLabel.y)
break;
case ItemDelegate.TextBesideIcon:
verify(iconImage)
verify(textLabel)
if (control.mirrored)
verify(textLabel.x < iconImage.x)
else
verify(iconImage.x < textLabel.x)
compare(iconImage.y, (control.availableHeight - iconImage.height) / 2)
compare(textLabel.y, (control.availableHeight - textLabel.height) / 2)
break;
}
}
}
|