blob: 1a90b8e7765b188d6033ce0661f737db7ec6d3a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
TEMPLATE = subdirs
QT_FOR_CONFIG += qml-private
SUBDIRS += \
qmlmin \
qmlimportscanner \
qmlcachegen
!android|android_app {
SUBDIRS += \
qml \
qmllint
qtConfig(qml-network):!contains(QT_CONFIG, no-qml-debug): SUBDIRS += qmlprofiler
qtHaveModule(quick) {
!static: {
SUBDIRS += \
qmlscene \
qmlplugindump \
qmltime
}
qtHaveModule(widgets): SUBDIRS += qmleasing
}
qtHaveModule(qmltest): SUBDIRS += qmltestrunner
qtConfig(private_tests): SUBDIRS += qmljs
}
qml.depends = qmlimportscanner
qmleasing.depends = qmlimportscanner
# qmlmin, qmlimportscanner & qmlcachegen are build tools.
# qmlscene is needed by the autotests.
# qmltestrunner may be useful for manual testing.
# qmlplugindump cannot be a build tool, because it loads target plugins.
# The other apps are mostly "desktop" tools and are thus excluded.
qtNomakeTools( \
qmlprofiler \
qmlplugindump \
qmleasing \
)
|
