blob: 96cf80405a2470a2561c05bd30fd1fce68d35211 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
TEMPLATE = subdirs
SUBDIRS += \
qmlmin \
qmlimportscanner
qmlmin.CONFIG = host_build
qmlimportscanner.CONFIG = host_build
!android|android_app {
SUBDIRS += \
qml \
qmlprofiler \
qmllint
qtHaveModule(quick) {
!static: {
SUBDIRS += \
qmlscene \
qmlplugindump \
qmltime
}
qtHaveModule(widgets): SUBDIRS += qmleasing
}
qtHaveModule(qmltest): SUBDIRS += qmltestrunner
contains(QT_CONFIG, private_tests): SUBDIRS += qmljs
}
qml.depends = qmlimportscanner
qmleasing.depends = qmlimportscanner
# qmlmin, qmlimportscanner & qmlbundle are build tools.
# qmlscene is needed by the autotests.
# qmltestrunner may be useful for manual testing.
# qmlplugindump cannot be a build tool, because it loads target plugins.
# The other apps are mostly "desktop" tools and are thus excluded.
qtNomakeTools( \
qmlprofiler \
qmlplugindump \
qmleasing \
)
|
