blob: 3f5f23eb3283c9297620c9efbc51c2a287d63b16 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
TEMPLATE = subdirs
QT_FOR_CONFIG += qml-private
qtConfig(qml-devtools) {
SUBDIRS += \
qmlmin \
qmlimportscanner
qtConfig(commandlineparser):qtConfig(xmlstreamwriter): SUBDIRS += qmlcachegen
}
qtConfig(thread):!android|android_app {
SUBDIRS += \
qml
qtConfig(qml-devtools): SUBDIRS += qmllint
qtConfig(qml-profiler): SUBDIRS += qmlprofiler
qtConfig(qml-preview): SUBDIRS += qmlpreview
qtHaveModule(quick) {
!static: {
SUBDIRS += \
qmlscene \
qmltime
qtConfig(regularexpression):qtConfig(process) {
SUBDIRS += \
qmlplugindump
}
}
qtHaveModule(widgets): SUBDIRS += qmleasing
}
qtHaveModule(qmltest): SUBDIRS += qmltestrunner
qtConfig(private_tests): SUBDIRS += qmljs
}
qtConfig(qml-devtools) {
qml.depends = qmlimportscanner
qmleasing.depends = qmlimportscanner
}
# qmlmin, qmlimportscanner & qmlcachegen are build tools.
# qmlscene is needed by the autotests.
# qmltestrunner may be useful for manual testing.
# qmlplugindump cannot be a build tool, because it loads target plugins.
# The other apps are mostly "desktop" tools and are thus excluded.
qtNomakeTools( \
qmlprofiler \
qmlplugindump \
qmleasing \
)
|
