1 files changed, 45 insertions, 0 deletions
diff --git a/src/qtdevicesettings/networksettingsplugin/networksettingsplugin.pro b/src/qtdevicesettings/networksettingsplugin/networksettingsplugin.pro
new file mode 100644
index 0000000..c514393
--- /dev/null
+++ b/src/qtdevicesettings/networksettingsplugin/networksettingsplugin.pro
@@ -0,0 +1,45 @@
+TEMPLATE = lib
+TARGET = networksettingsplugin
+QT += qml quick
+CONFIG += qt plugin
+
+uri = com.theqtcompany.settings.network
+
+include(networksettings/networksettings.pri)
+
+# Input
+SOURCES += \
+    networksettingsplugin_plugin.cpp
+HEADERS += \
+    networksettingsplugin_plugin.h
+
+DISTFILES = qmldir
+
+!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
+    copy_qmldir.target = $$OUT_PWD/qmldir
+    copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
+    copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
+    QMAKE_EXTRA_TARGETS += copy_qmldir
+    PRE_TARGETDEPS += $$copy_qmldir.target
+}
+
+qmldir.files = qmldir
+
+pluginfiles.files += \
+    imports/NetworkSettings/EditWiredSettings.qml \
+    imports/NetworkSettings/NetworkDetails.qml \
+    imports/NetworkSettings/WifiSettings.qml \
+    imports/NetworkSettings/IpAddressTextField.qml \
+    imports/NetworkSettings/NetworkSettings.qml \
+    imports/NetworkSettings/WiredSettings.qml
+
+installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
+
+pluginfiles.path = $$installPath
+qmldir.path = $$installPath
+target.path = $$installPath
+INSTALLS += target qmldir pluginfiles
+
+RESOURCES += \
+    icons.qrc
+