1 files changed, 38 insertions, 0 deletions
diff --git a/src/settingsui/settingsuiplugin/settingsuiplugin.pro b/src/settingsui/settingsuiplugin/settingsuiplugin.pro
new file mode 100644
index 0000000..5b11241
--- /dev/null
+++ b/src/settingsui/settingsuiplugin/settingsuiplugin.pro
@@ -0,0 +1,38 @@
+TEMPLATE = lib
+TARGET = settingsuiplugin
+QT += qml quick
+CONFIG += qt plugin c++11
+
+TARGET = $$qtLibraryTarget($$TARGET)
+uri = QtDeviceUtilities.SettingsUI
+
+# Input
+SOURCES += \
+    settingsuiplugin_plugin.cpp
+
+HEADERS += \
+    settingsuiplugin_plugin.h
+
+DISTFILES += \
+    qmldir
+
+!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
+    copy_qmldir.target = $$OUT_PWD/qmldir
+    copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
+    copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
+    QMAKE_EXTRA_TARGETS += copy_qmldir
+    PRE_TARGETDEPS += $$copy_qmldir.target
+}
+
+qmldir.files = qmldir
+
+unix {
+    installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
+    qmldir.path = $$installPath
+    target.path = $$installPath
+    INSTALLS += target qmldir
+}
+
+RESOURCES += \
+    icons.qrc \
+    plugin.qrc