summaryrefslogtreecommitdiffstats
path: root/src/settingsui/network/EditWiredSettings.qml
blob: 48a6abb80cf73a7af265df1792cab038c1b0b62c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
/****************************************************************************
**
** Copyright (C) 2015 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the Qt Device Utilities module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.6
import QtQuick.Layouts 1.3
import Qt.labs.controls 1.0
import Qt.labs.controls.material 1.0
import Qt.labs.controls.universal 1.0
import com.theqtcompany.settings.network 1.0

Item {
    id: root
    property string title: qsTr("Ethernet Settings")
    property var service: undefined
    property bool ipv4Changed: false
    property bool ipv6Changed: false
    property bool nameserversChanged: false
    property bool domainsChanged: false
    property bool proxyChanged: false

    Component.onDestruction: {
        //Clear all unsaved changes from models
        service.proxy.excludes.resetChanges();
        service.nameservers.resetChanges();
        service.domains.resetChanges();
    }

    Component.onCompleted: titlebar.title = service.name;

    Flickable {
        anchors.fill: parent
        anchors.top: saveButton.bottom
        anchors.margins: 20
        contentHeight: content.height
        contentWidth: width

        Column {
            id: content
            width: parent.width
            spacing: 10
            property int titleWidth: width * 0.382
            property int groupWidth: width - saveButton.width - 10

            //IPv4 Config
            GroupBox {
                width: content.groupWidth
                Layout.fillWidth: true
                title: qsTr("IPv4")

                ColumnLayout {
                    anchors.fill: parent

                    ComboBoxEntry {
                        title:  qsTr("Connection method:")
                        titleWidth: content.titleWidth
                        model: ListModel {
                            id: methodsModel

                            ListElement {
                                text: "DHCP"
                                method: NetworkSettingsIPv4.Dhcp
                            }
                            ListElement {
                                text: "Manual"
                                method: NetworkSettingsIPv4.Manual
                            }
                            ListElement {
                                text: "Off"
                                method: NetworkSettingsIPv4.Off
                            }
                        }
                        Component.onCompleted: currentIndex = service.ipv4.method
                        onCurrentIndexChanged: {
                            ipv4Changed = true;
                            service.ipv4.method = model.get(currentIndex).method;
                        }
                    }

                    GridLayout {
                        columnSpacing: 10
                        rows: 3
                        columns: 2
                        visible: service.ipv4.method !== NetworkSettingsIPv4.Off
                        width: parent.width

                        Label {
                            text: qsTr("Address:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        IpAddressTextField {
                            id: ipv4Address
                            text: service.ipv4.address
                            onTextChanged: ipv4Changed = true;
                            onAccepted: if (text.length > 0) service.ipv4.address = text
                            enabled: service.ipv4.method === NetworkSettingsIPv4.Manual
                        }
                        Label {
                            text: qsTr("Mask:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        IpAddressTextField {
                            id: ipv4Mask
                            text: service.ipv4.mask
                            onTextChanged: ipv4Changed = true;
                            onAccepted: if (text.length > 0) service.ipv4.mask = text
                            enabled: service.ipv4.method === NetworkSettingsIPv4.Manual
                        }
                        Label {
                            text: qsTr("Router:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        IpAddressTextField {
                            id: ipv4Gateway
                            text: service.ipv4.gateway
                            onTextChanged: ipv4Changed = true
                            onAccepted: if (text.length > 0) service.ipv4.gateway = text
                            enabled: service.ipv4.method === NetworkSettingsIPv4.Manual
                        }
                    }
                }
            }

            //IPv6 Config
            GroupBox {
                width: content.groupWidth
                Layout.fillWidth: true
                title: qsTr("IPv6")

                ColumnLayout {
                    anchors.fill: parent

                    ComboBoxEntry {
                        title: qsTr("Connection method:")
                        titleWidth: content.titleWidth
                        model: ListModel {
                            id: ipv6methodsmodel

                            ListElement {
                                text: qsTr("Auto")
                                method: NetworkSettingsIPv6.Auto
                            }
                            ListElement {
                                text: qsTr("Manual")
                                method: NetworkSettingsIPv6.Manual
                            }
                            ListElement {
                                text: qsTr("Off")
                                method: NetworkSettingsIPv6.Off
                            }
                        }

                        Component.onCompleted: currentIndex = service.ipv6.method

                        onCurrentIndexChanged: {
                            ipv6Changed = true;
                            service.ipv6.method = model.get(currentIndex).method;
                        }
                    }
                    GridLayout {
                        columnSpacing: 10
                        rows: 3
                        columns: 2
                        visible: service.ipv6.method !== NetworkSettingsIPv6.Off

                        Label {
                            text: qsTr("Address:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        TextField {
                            id: ipv6Address
                            text: service.ipv6.address
                            Layout.fillWidth: true
                            onTextChanged: ipv6Changed = true;
                            onAccepted: if (text.length > 0) service.ipv6.address = text
                            enabled: service.ipv6.method === NetworkSettingsIPv6.Manual
                        }
                        Label {
                            text: qsTr("Router:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        TextField {
                            id: ipv6Gateway
                            text: service.ipv6.gateway
                            Layout.fillWidth: true
                            onTextChanged: ipv6Changed = true;
                            onAccepted: if (text.length > 0) service.ipv4.gateway = text
                            enabled: service.ipv6.method === NetworkSettingsIPv6.Manual
                        }
                        Label {
                            text: qsTr("Prefix length:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                        }
                        TextField {
                            id: ipv6PrefixLength
                            text: service.ipv6.prefixLength
                            Layout.fillWidth: true
                            validator: IntValidator { bottom: 0; top: 255 }
                            onTextChanged: ipv6Changed = true
                            onAccepted: if (text.length > 0) service.ipv6.prefixLength = parseInt(text)
                            enabled: service.ipv6.method === NetworkSettingsIPv6.Manual
                        }
                    }
                }
            }
            GroupBox {
                width: content.groupWidth
                Layout.fillWidth: true
                title: qsTr("Name servers")

                ColumnLayout {
                    anchors.fill: parent
                    AddressListEntry {
                        title: qsTr("Address:")
                        model: service.nameservers
                        modified: nameserversChanged
                    }
                }
            }
            GroupBox {
                width: content.groupWidth
                Layout.fillWidth: true
                title: qsTr("Domains")

                ColumnLayout {
                    anchors.fill: parent
                    AddressListEntry {
                        title: qsTr("Address:")
                        model: service.domains
                        modified: domainsChanged
                    }
                }
            }
            GroupBox {
                width: content.groupWidth
                Layout.fillWidth: true
                title: qsTr("Proxy Settings")

                ColumnLayout {
                    id: proxyLayout
                    width: parent.width

                    ComboBoxEntry {
                        title: qsTr("Configuration:")
                        titleWidth: content.titleWidth
                        model: ListModel {
                            id: proxyMethodModel

                            ListElement {
                                text: qsTr("Direct")
                                method: NetworkSettingsProxy.Direct
                            }
                            ListElement {
                                text: qsTr("Auto")
                                method: NetworkSettingsProxy.Auto
                            }
                            ListElement {
                                text: qsTr("Manual")
                                method: NetworkSettingsProxy.Manual
                            }
                        }
                        Component.onCompleted: currentIndex = service.proxy.method

                        onCurrentIndexChanged: {
                            proxyChanged = true;
                            service.proxy.method = model.get(currentIndex).method;
                        }
                    }
                    RowLayout {
                        spacing: 10
                        visible: service.proxy.method !== NetworkSettingsProxy.Direct

                        Label {
                            text: service.proxy.method === NetworkSettingsProxy.Manual ? qsTr("Proxy address:") : qsTr("Configuration URL:")
                            Layout.preferredWidth: content.titleWidth
                            horizontalAlignment: Text.AlignRight
                            Layout.alignment: Qt.AlignVCenter
                            elide: Label.ElideRight
                        }
                        TextField {
                            id: proxyUrl
                            text: service.proxy.url
                            Layout.fillWidth: true
                            onTextChanged: proxyChanged = true;
                            onAccepted: service.proxy.url = text;
                        }
                    }
                    AddressListEntry {
                        model: service.proxy.excludes
                        modified: proxyChanged
                        title: qsTr("No proxy for:")
                        visible: service.proxy.method === NetworkSettingsProxy.Manual
                    }
                }
            }
        }
    }
    Button {
        id: saveButton
        anchors.right: parent.right
        anchors.top: parent.top
        anchors.margins: 20
        text: qsTr("Save")

        onClicked: {
            if (ipv4Changed) {
                ipv4Address.accepted();
                ipv4Mask.accepted();
                ipv4Gateway.accepted();
                service.setupIpv4Config();
            }

            if (ipv6Changed) {
                ipv6Address.accepted();
                ipv6Gateway.accepted();
                ipv6PrefixLength.accepted();
                service.setupIpv6Config();
            }

            if (nameserversChanged) {
                service.setupNameserversConfig();
            }

            if (domainsChanged) {
                service.setupDomainsConfig();
            }

            if (proxyChanged) {
                proxyUrl.accepted();
                service.setupNetworkSettingsProxy();
            }
            stackView.pop();
        }
    }
}