summaryrefslogtreecommitdiffstats
path: root/src/settingsui/network/WiredSettings.qml
blob: f5d3a8fc6d80574283822518b350cb52a7a04fea (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
/****************************************************************************
**
** Copyright (C) 2016 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Device Utilities module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:GPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick
import QtQuick.Layouts
import QtQuick.Controls
import QtDeviceUtilities.NetworkSettings

Item {
    id: root
    anchors.fill: parent
    property bool editMode: false
    property var service: null
    property string title: qsTr("Network");

    Component.onCompleted: {
        NetworkSettingsManager.services.type = NetworkSettingsType.Wired;
        root.service = NetworkSettingsManager.services.itemFromRow(0);
        ipv4Method.currentIndex = service.ipv4.method
    }

    onServiceChanged: {
        NetworkSettingsManager.services.type = NetworkSettingsType.Wired;
        if (!root.service) {
            root.service = NetworkSettingsManager.services.itemFromRow(0);
        }
    }

    GroupBox {
        title: qsTr("Ethernet Connection")
        anchors.fill: parent

        Column {
            spacing: 10
            width: parent.width

            ComboBoxEntry {
                id: ipv4Method
                title: qsTr("Connection method:")
                model: ListModel {
                    id: methodsModel

                    ListElement {
                        text: "DHCP"
                        method: NetworkSettingsIPv4.Dhcp
                    }
                    ListElement {
                        text: "Manual"
                        method: NetworkSettingsIPv4.Manual
                    }
                    ListElement {
                        text: "Off"
                        method: NetworkSettingsIPv4.Off
                    }
                }

                Component.onCompleted: currentIndex = service.ipv4.method
                onCurrentIndexChanged: {
                    if (model.get(currentIndex).method !== NetworkSettingsIPv4.Dhcp) {
                        service.ipv4.method = model.get(currentIndex).method;
                        editMode = true;
                    }
                    else if (service){
                        //Enable DHCP
                        if (service.ipv4.method !== model.get(currentIndex).method) {
                            service.ipv4.method = model.get(currentIndex).method;
                            service.setupIpv4Config();
                        }
                        editMode = false;
                    }
                }
            }
            Item {
                width: parent.width
                height: gridLayout.implicitHeight
                GridLayout {
                    id: gridLayout
                    columns: 2
                    rows: 4
                    width: parent.width
                    visible: service.ipv4.method !== NetworkSettingsIPv4.Off

                    Label {
                        text: qsTr("IP Address: ")
                        width: parent.width * .3
                    }
                    IpAddressTextField {
                        id: ipv4Address
                        text: service.ipv4.address
                        enabled: editMode
                        onAccepted: if (text.length > 0) service.ipv4.address = text
                    }
                    Label {
                        text: qsTr("Mask: ")
                    }
                    IpAddressTextField {
                        id: ipv4Mask
                        text: service.ipv4.mask
                        enabled: editMode
                        onAccepted: if (text.length > 0) service.ipv4.mask = text
                    }
                    Label {
                        text: qsTr("Router: ")
                    }
                    IpAddressTextField {
                        id: ipv4Gateway
                        text: service.ipv4.gateway
                        enabled: editMode
                        onAccepted: if (text.length > 0) service.ipv4.gateway = text
                    }
                    Label {
                        Layout.alignment: Qt.AlignTop
                        text: qsTr("DNS server: ")
                    }
                    Column {
                        spacing: 10
                        Layout.fillWidth: true
                        Layout.alignment: Qt.AlignTop

                        Repeater {
                            model: service.nameservers

                            Label {
                                text: display
                            }
                        }
                    }
                }
                MouseArea {
                    anchors.fill: parent
                    enabled: !editMode
                             && methodsModel.get(ipv4Method.currentIndex).method === NetworkSettingsIPv4.Manual
                    onClicked: editMode = true
                }
            }
            Row {
                spacing: 10
                Button {
                    text: qsTr("Save")
                    visible: editMode

                    onClicked: {
                        ipv4Address.accepted();
                        ipv4Mask.accepted();
                        ipv4Gateway.accepted();
                        service.setupIpv4Config();
                        editMode = false;
                    }
                }
                Button {
                    text: qsTr("Cancel")
                    visible: editMode
                    onClicked: {
                        editMode = false;
                        ipv4Method.currentIndex = service.ipv4.method
                    }
                }
            }
            Button {
                text: qsTr("Edit")
                visible: !editMode
                onClicked: stackView.push(Qt.resolvedUrl("EditWiredSettings.qml"), {service: root.service});
            }
        }
    }
}