src/src.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

TEMPLATE = subdirs

SUBDIRS += positioning

plugins.depends = positioning
SUBDIRS += plugins

contains(QT_CONFIG, private_tests) {
    positioning_doc_snippets.subdir = positioning/doc/snippets
    #plugin dependency required during static builds
    positioning_doc_snippets.depends = positioning plugins

    SUBDIRS += positioning_doc_snippets
}

#no point in building QtLocation without Qt3D
qtHaveModule(3d) {
    SUBDIRS += 3rdparty

    location.depends = positioning 3rdparty
    SUBDIRS += location

    plugins.depends += location
    qtHaveModule(quick):imports.depends += location

    contains(QT_CONFIG, private_tests) {
        location_doc_snippets.subdir = location/doc/snippets
        #plugin dependency required during static builds
        location_doc_snippets.depends = location plugins

        SUBDIRS += location_doc_snippets
    }
}

qtHaveModule(quick) {
    imports.depends += positioning
    SUBDIRS += imports
}