Add an example media player written in QML

Change-Id: I98c35b3888701f94efaf58b3ab6c08c39943bdf8
Reviewed-by: Lars Knoll <lars.knoll@qt.io>

1 files changed, 176 insertions, 0 deletions

diff --git a/examples/multimedia/video/mediaplayer/PlaybackControl.qml b/examples/multimedia/video/mediaplayer/PlaybackControl.qml
new file mode 100644
index 000000000..51e4e794d
--- /dev/null
+++ b/examples/multimedia/video/mediaplayer/PlaybackControl.qml
@@ -0,0 +1,176 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import QtMultimedia
+
+Item {
+    id: root
+
+    required property MediaPlayer mediaPlayer
+    property int mediaPlayerState: mediaPlayer.playbackState
+
+    implicitHeight: 80
+    opacity: 1
+
+    Behavior on opacity { NumberAnimation { duration: 300 }}
+
+    function updateOpacity() {
+        if (playbackControlHoover.hovered || mediaPlayerState != MediaPlayer.PlayingState || !mediaPlayer.hasVideo)
+            root.opacity = 1;
+        else
+            root.opacity = 0;
+    }
+
+    Connections {
+        target: mediaPlayer
+        function onPlaybackStateChanged() { updateOpacity() }
+        function onHasVideoChanged() { updateOpacity() }
+    }
+
+    HoverHandler {
+        id: playbackControlHoover
+        margin: 50
+        onHoveredChanged: updateOpacity()
+    }
+
+    Frame {
+        anchors.fill: parent
+
+        background: Rectangle {
+            color: "white"
+        }
+
+        ColumnLayout {
+            id: playbackControlPanel
+            anchors.fill: parent
+            anchors.leftMargin: 10
+            anchors.rightMargin: 10
+
+            PlaybackSeekControl {
+                Layout.fillWidth: true
+                mediaPlayer: root.mediaPlayer
+            }
+
+            Item {
+                id: playerButtons
+
+                Layout.fillWidth: true
+                Layout.fillHeight: true
+
+                PlaybackRateControl {
+                    anchors.left: parent.left
+                    anchors.top: parent.top
+                    anchors.bottom: parent.bottom
+                    mediaPlayer: root.mediaPlayer
+                }
+
+                RowLayout {
+                    anchors.centerIn: parent
+                    RoundButton {
+                        id: pauseButton
+                        radius: 50.0
+                        text: "\u2016";
+                        onClicked: mediaPlayer.pause()
+                    }
+
+                    RoundButton {
+                        id: playButton
+                        radius: 50.0
+                        text: "\u25B6";
+                        onClicked: mediaPlayer.play()
+                    }
+
+                    RoundButton {
+                        id: stopButton
+                        radius: 50.0
+                        text: "\u25A0";
+                        onClicked: mediaPlayer.stop()
+                    }
+                }
+
+                AudioControl {
+                    anchors.right: parent.right
+                    anchors.top: parent.top
+                    anchors.bottom: parent.bottom
+                    mediaPlayer: root.mediaPlayer
+                }
+            }
+        }
+    }
+
+    states: [
+        State {
+            name: "playing"
+            when: mediaPlayerState == MediaPlayer.PlayingState
+            PropertyChanges { target: pauseButton; visible: true}
+            PropertyChanges { target: playButton; visible: false}
+            PropertyChanges { target: stopButton; visible: true}
+        },
+        State {
+            name: "stopped"
+            when: mediaPlayerState == MediaPlayer.StoppedState
+            PropertyChanges { target: pauseButton; visible: false}
+            PropertyChanges { target: playButton; visible: true}
+            PropertyChanges { target: stopButton; visible: false}
+        },
+        State {
+            name: "paused"
+            when: mediaPlayerState == MediaPlayer.PausedState
+            PropertyChanges { target: pauseButton; visible: false}
+            PropertyChanges { target: playButton; visible: true}
+            PropertyChanges { target: stopButton; visible: true}
+        }
+    ]
+
+}
+