Initial copy of QtMultimediaKit.

Comes from original repo, with SHA1:
2c82d5611655e5967f5c5095af50c0991c4378b2

1 files changed, 46 insertions, 0 deletions

diff --git a/src/plugins/plugins.pro b/src/plugins/plugins.pro
new file mode 100644
index 000000000..5a96fded0
--- /dev/null
+++ b/src/plugins/plugins.pro
@@ -0,0 +1,46 @@
+######################################################################
+#
+# Mobility API project - multimedia 
+#
+######################################################################
+
+TEMPLATE = subdirs
+
+SUBDIRS += m3u
+
+win32 {
+    SUBDIRS += audiocapture
+}
+
+win32:!wince* {
+    contains(directshow_enabled, yes): SUBDIRS += directshow
+}
+
+simulator: SUBDIRS += simulator
+
+unix:!mac:!symbian {
+    TMP_GST_LIBS = \
+        gstreamer-0.10 >= 0.10.19 \
+        gstreamer-base-0.10 >= 0.10.19 \
+        gstreamer-interfaces-0.10 >= 0.10.19 \
+        gstreamer-audio-0.10 >= 0.10.19 \
+        gstreamer-video-0.10 >= 0.10.19
+
+    system(pkg-config --exists \'$${TMP_GST_LIBS}\' --print-errors): {
+        SUBDIRS += gstreamer
+    } else {
+        SUBDIRS += audiocapture
+    }
+
+    !maemo*:SUBDIRS += v4l
+
+    contains(pulseaudio_enabled, yes) {
+        SUBDIRS += pulseaudio
+    }
+}
+
+mac:!simulator {
+    SUBDIRS += audiocapture qt7
+}
+
+symbian:SUBDIRS += symbian