Move qtmultimedia over to the new config system

Use the new configuration system to define external
libraries, configure tests and features. Don't use
pkg-config outside of the configuration step. And
move all command line options over from qtbase, so
that we can remove them from there in a second step.

Change-Id: I1aa4b557a6aee17eeceb00602005a2d28b426a26
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io>
Reviewed-by: Yoann Lopes <yoann.lopes@qt.io>

15 files changed, 47 insertions, 55 deletions

diff --git a/src/plugins/avfoundation/camera/camera.pro b/src/plugins/avfoundation/camera/camera.pro
index a17ff5a73..ab70c25c3 100644
--- a/src/plugins/avfoundation/camera/camera.pro
+++ b/src/plugins/avfoundation/camera/camera.pro
@@ -8,12 +8,13 @@ QT += multimedia-private network
 LIBS += -framework AudioToolbox \
         -framework CoreAudio \
         -framework QuartzCore \
-        -framework AVFoundation \
         -framework CoreMedia
 osx:LIBS += -framework AppKit \
             -framework AudioUnit
 ios:LIBS += -framework CoreVideo
 
+QMAKE_USE += avfoundation
+
 OTHER_FILES += avfcamera.json
 
 DEFINES += QMEDIA_AVF_CAMERA
diff --git a/src/plugins/avfoundation/mediaplayer/mediaplayer.pro b/src/plugins/avfoundation/mediaplayer/mediaplayer.pro
index 29e231066..f9a086b33 100644
--- a/src/plugins/avfoundation/mediaplayer/mediaplayer.pro
+++ b/src/plugins/avfoundation/mediaplayer/mediaplayer.pro
@@ -6,7 +6,9 @@ CONFIG += no_keywords
 
 QT += multimedia-private network
 
-LIBS += -framework AVFoundation -framework CoreMedia -framework CoreVideo -framework QuartzCore
+LIBS += -framework CoreMedia -framework CoreVideo -framework QuartzCore
+
+QMAKE_USE += avfoundation
 
 DEFINES += QMEDIA_AVF_MEDIAPLAYER
 
diff --git a/src/plugins/directshow/camera/camera.pri b/src/plugins/directshow/camera/camera.pri
index 6c67a8fe2..fb7fbd3f5 100644
--- a/src/plugins/directshow/camera/camera.pri
+++ b/src/plugins/directshow/camera/camera.pri
@@ -28,4 +28,4 @@ SOURCES += \
     $$PWD/dscameraimageprocessingcontrol.cpp
 
 *-msvc*:INCLUDEPATH += $$(DXSDK_DIR)/include
-LIBS += -lstrmiids -ldmoguids -luuid -lmsdmo -lole32 -loleaut32
+QMAKE_USE += directshow
diff --git a/src/plugins/directshow/directshow.pro b/src/plugins/directshow/directshow.pro
index 918a14210..5eb4fbc96 100644
--- a/src/plugins/directshow/directshow.pro
+++ b/src/plugins/directshow/directshow.pro
@@ -1,19 +1,19 @@
 TARGET = dsengine
+QT += multimedia-private
+
 win32:!qtHaveModule(opengl)|qtConfig(dynamicgl) {
     LIBS_PRIVATE += -lgdi32 -luser32
 }
 
-QT += multimedia-private
-
 HEADERS += dsserviceplugin.h
 SOURCES += dsserviceplugin.cpp
 
-!config_wmsdk: DEFINES += QT_NO_WMSDK
+!qtConfig(wmsdk): DEFINES += QT_NO_WMSDK
 
 mingw: DEFINES += NO_DSHOW_STRSAFE
 
 include(helpers/helpers.pri)
-!config_wmf|!contains(QT_CONFIG, wmf-backend): include(player/player.pri)
+!qtConfig(wmf-backend): include(player/player.pri)
 include(camera/camera.pri)
 
 OTHER_FILES += \
diff --git a/src/plugins/directshow/player/player.pri b/src/plugins/directshow/player/player.pri
index 8b4bb70b7..7391ec7f0 100644
--- a/src/plugins/directshow/player/player.pri
+++ b/src/plugins/directshow/player/player.pri
@@ -1,7 +1,7 @@
 INCLUDEPATH += $$PWD
 
-LIBS += -lstrmiids -ldmoguids -luuid -lole32 -loleaut32 -lmsdmo -lgdi32
-
+QMAKE_USE += directshow
+LIBS += -lgdi32
 
 qtHaveModule(widgets): QT += widgets
 
@@ -29,7 +29,7 @@ SOURCES += \
         $$PWD/directshowmetadatacontrol.cpp \
         $$PWD/vmr9videowindowcontrol.cpp
 
-config_evr {
+qtConfig(evr) {
     DEFINES += HAVE_EVR
 
     include($$PWD/../../common/evr.pri)
@@ -41,7 +41,7 @@ config_evr {
         $$PWD/directshowevrvideowindowcontrol.cpp
 }
 
-config_wshellitem {
+qtConfig(wshellitem) {
     QT += core-private
 } else {
     DEFINES += QT_NO_SHELLITEM
diff --git a/src/plugins/gstreamer/camerabin/camerabin.pro b/src/plugins/gstreamer/camerabin/camerabin.pro
index 214489f3e..3a5fcc02f 100644
--- a/src/plugins/gstreamer/camerabin/camerabin.pro
+++ b/src/plugins/gstreamer/camerabin/camerabin.pro
@@ -62,7 +62,7 @@ maemo6 {
     CONFIG += have_gst_photography
 }
 
-config_gstreamer_photography {
+qtConfig(gstreamer_photography) {
     DEFINES += HAVE_GST_PHOTOGRAPHY
 
     HEADERS += \
@@ -77,15 +77,15 @@ config_gstreamer_photography {
         $$PWD/camerabinfocus.cpp \
         $$PWD/camerabinlocks.cpp
 
-    LIBS += -lgstphotography-$$GST_VERSION
+    QMAKE_USE += gstreamer_photography
     DEFINES += GST_USE_UNSTABLE_API #prevents warnings because of unstable photography API
 }
 
-config_gstreamer_encodingprofiles {
+qtConfig(gstreamer_encodingprofiles) {
     DEFINES += HAVE_GST_ENCODING_PROFILES
 }
 
-config_linux_v4l: {
+qtConfig(linux_v4l) {
     DEFINES += USE_V4L
 
     HEADERS += \
diff --git a/src/plugins/gstreamer/common.pri b/src/plugins/gstreamer/common.pri
index babdb7cfb..7faf9b111 100644
--- a/src/plugins/gstreamer/common.pri
+++ b/src/plugins/gstreamer/common.pri
@@ -1,4 +1,3 @@
-
 QT += core-private multimedia-private network
 
 qtHaveModule(widgets) {
@@ -8,30 +7,19 @@ qtHaveModule(widgets) {
 
 LIBS += -lqgsttools_p
 
-CONFIG += link_pkgconfig
-
-PKGCONFIG += \
-    gstreamer-$$GST_VERSION \
-    gstreamer-base-$$GST_VERSION \
-    gstreamer-audio-$$GST_VERSION \
-    gstreamer-video-$$GST_VERSION \
-    gstreamer-pbutils-$$GST_VERSION
-
-maemo*:PKGCONFIG +=gstreamer-plugins-bad-$$GST_VERSION
+QMAKE_USE += gstreamer
 
 mir: {
     DEFINES += HAVE_MIR
 }
 
-
-config_resourcepolicy {
+qtConfig(resourcepolicy) {
+    QMAKE_USE += libresourceqt5
     DEFINES += HAVE_RESOURCE_POLICY
-    PKGCONFIG += libresourceqt5
 }
 
-config_gstreamer_appsrc {
-    PKGCONFIG += gstreamer-app-$$GST_VERSION
+qtConfig(gstreamer_app) {
+    QMAKE_USE += gstreamer_app
     DEFINES += HAVE_GST_APPSRC
-    LIBS += -lgstapp-$$GST_VERSION
 }
 
diff --git a/src/plugins/gstreamer/mediacapture/mediacapture.pro b/src/plugins/gstreamer/mediacapture/mediacapture.pro
index db5210d4d..17248a495 100644
--- a/src/plugins/gstreamer/mediacapture/mediacapture.pro
+++ b/src/plugins/gstreamer/mediacapture/mediacapture.pro
@@ -31,7 +31,7 @@ SOURCES += $$PWD/qgstreamercaptureservice.cpp \
 # Camera usage with gstreamer needs to have
 #CONFIG += use_gstreamer_camera
 
-use_gstreamer_camera:config_linux_v4l {
+use_gstreamer_camera:qtConfig(linux_v4l) {
     DEFINES += USE_GSTREAMER_CAMERA
 
     OTHER_FILES += \
diff --git a/src/plugins/plugins.pro b/src/plugins/plugins.pro
index f113f68b3..b0c5101b6 100644
--- a/src/plugins/plugins.pro
+++ b/src/plugins/plugins.pro
@@ -5,6 +5,7 @@
 ######################################################################
 
 TEMPLATE = subdirs
+QT_FOR_CONFIG += multimedia-private
 
 SUBDIRS += m3u
 
@@ -17,7 +18,7 @@ android {
 }
 
 qnx {
-    config_mmrenderer: SUBDIRS += qnx
+    qtConfig(mmrenderer): SUBDIRS += qnx
     SUBDIRS += audiocapture
 }
 
@@ -26,44 +27,44 @@ qnx:!blackberry {
 }
 
 win32 {
-    config_wasapi: SUBDIRS += wasapi
+    qtConfig(wasapi): SUBDIRS += wasapi
 }
 
 win32:!winrt {
     SUBDIRS += audiocapture \
                windowsaudio
 
-    config_directshow: SUBDIRS += directshow
-    config_wmf: SUBDIRS += wmf
+    qtConfig(directshow): SUBDIRS += directshow
+    qtConfig(wmf-backend): SUBDIRS += wmf
 }
 
+
 winrt {
     SUBDIRS += winrt
 }
 
 unix:!mac:!android {
-    config_gstreamer {
+    qtConfig(gstreamer) {
        SUBDIRS += gstreamer
     } else {
         SUBDIRS += audiocapture
     }
 
-    config_pulseaudio: SUBDIRS += pulseaudio
-    config_alsa: SUBDIRS += alsa
+    qtConfig(pulseaudio): SUBDIRS += pulseaudio
+    qtConfig(alsa): SUBDIRS += alsa
 
     # v4l is turned off because it is not supported in Qt 5
-    # config_linux_v4l {
+    # qtConfig(linux_v4l) {
     #     !maemo*:SUBDIRS += v4l
     # }
 }
 
 darwin:!watchos {
     SUBDIRS += audiocapture coreaudio
-
-    config_avfoundation: SUBDIRS += avfoundation
+    qtConfig(avfoundation): SUBDIRS += avfoundation
 }
 
-config_resourcepolicy {
+qtConfig(resourcepolicy) {
     SUBDIRS += resourcepolicy
 }
 
diff --git a/src/plugins/pulseaudio/pulseaudio.pro b/src/plugins/pulseaudio/pulseaudio.pro
index 7f4d3de22..c6339e9e8 100644
--- a/src/plugins/pulseaudio/pulseaudio.pro
+++ b/src/plugins/pulseaudio/pulseaudio.pro
@@ -1,8 +1,7 @@
 TARGET = qtmedia_pulse
 QT += multimedia-private
 
-CONFIG += link_pkgconfig
-PKGCONFIG += libpulse
+QMAKE_USE += pulseaudio
 
 HEADERS += qpulseaudioplugin.h \
            qaudiodeviceinfo_pulse.h \
diff --git a/src/plugins/qnx/mediaplayer/mediaplayer.pri b/src/plugins/qnx/mediaplayer/mediaplayer.pri
index 9dedab0fd..9d74dd481 100644
--- a/src/plugins/qnx/mediaplayer/mediaplayer.pri
+++ b/src/plugins/qnx/mediaplayer/mediaplayer.pri
@@ -18,7 +18,7 @@ SOURCES += \
     $$PWD/mmrendererutil.cpp \
     $$PWD/mmrenderervideowindowcontrol.cpp
 
-LIBS += -lmmrndclient -lstrm
+QMAKE_USE += mmrenderer
 
 blackberry {
     HEADERS += $$PWD/bpsmediaplayercontrol.h
diff --git a/src/plugins/resourcepolicy/resourcepolicy.pro b/src/plugins/resourcepolicy/resourcepolicy.pro
index 91a946665..89e75be1b 100644
--- a/src/plugins/resourcepolicy/resourcepolicy.pro
+++ b/src/plugins/resourcepolicy/resourcepolicy.pro
@@ -1,8 +1,8 @@
 TARGET = resourceqt
 
 QT += multimedia-private
-CONFIG += link_pkgconfig
-PKGCONFIG += libresourceqt5
+
+QMAKE_USE += libresourceqt5
 
 INCLUDEPATH += $$PWD \
     $${SOURCE_DIR}/src/multimedia
diff --git a/src/plugins/videonode/videonode.pro b/src/plugins/videonode/videonode.pro
index 5fbcaecd4..ab7295406 100644
--- a/src/plugins/videonode/videonode.pro
+++ b/src/plugins/videonode/videonode.pro
@@ -1,7 +1,7 @@
 TEMPLATE = subdirs
-QT_FOR_CONFIG += gui-private
+QT_FOR_CONFIG += gui-private multimedia-private
 
-config_gpu_vivante {
+qtConfig(gpu_vivante) {
     SUBDIRS += imx6
 }
 
diff --git a/src/plugins/wmf/decoder/decoder.pri b/src/plugins/wmf/decoder/decoder.pri
index 992e710fe..7637ac848 100644
--- a/src/plugins/wmf/decoder/decoder.pri
+++ b/src/plugins/wmf/decoder/decoder.pri
@@ -1,7 +1,7 @@
 INCLUDEPATH += $$PWD
 
-LIBS += -lstrmiids -ldmoguids -luuid -lmsdmo -lole32 -loleaut32 -lMf -lMfuuid -lMfplat \
-        -lPropsys -lmfreadwrite -lwmcodecdspuuid
+LIBS += -lmfreadwrite -lwmcodecdspuuid
+QMAKE_USE += wmf
 
 HEADERS += \
     $$PWD/mfdecoderservice.h \
@@ -11,4 +11,4 @@ HEADERS += \
 SOURCES += \
     $$PWD/mfdecoderservice.cpp \
     $$PWD/mfdecodersourcereader.cpp \
-    $$PWD/mfaudiodecodercontrol.cpp
\ No newline at end of file
+    $$PWD/mfaudiodecodercontrol.cpp
diff --git a/src/plugins/wmf/player/player.pri b/src/plugins/wmf/player/player.pri
index a10e2df60..38ccb82a6 100644
--- a/src/plugins/wmf/player/player.pri
+++ b/src/plugins/wmf/player/player.pri
@@ -1,6 +1,7 @@
 INCLUDEPATH += $$PWD
 
-LIBS += -lstrmiids -ldmoguids -luuid -lmsdmo -lgdi32 -luser32 -lole32 -loleaut32 -lMf -lMfuuid -lMfplat -lPropsys
+LIBS += -lgdi32 -luser32
+QMAKE_USE += wmf
 
 DEFINES += QMEDIA_MEDIAFOUNDATION_PLAYER