1 files changed, 118 insertions, 0 deletions
diff --git a/src/multimedia/platform/darwin/camera/avfimagecapturecontrol.mm b/src/multimedia/platform/darwin/camera/avfimagecapturecontrol.mm
index ddcf693b5..79576b779 100644
--- a/src/multimedia/platform/darwin/camera/avfimagecapturecontrol.mm
+++ b/src/multimedia/platform/darwin/camera/avfimagecapturecontrol.mm
@@ -275,4 +275,122 @@ void AVFImageCaptureControl::updateCaptureConnection()
     }
 }
 
+
+QImageEncoderSettings AVFImageCaptureControl::imageSettings() const
+{
+    QImageEncoderSettings settings;
+
+    if (!videoCaptureDeviceIsValid())
+        return settings;
+
+    AVCaptureDevice *captureDevice = m_service->session()->videoCaptureDevice();
+    if (!captureDevice.activeFormat) {
+        qDebugCamera() << Q_FUNC_INFO << "no active format";
+        return settings;
+    }
+
+    QSize res(qt_device_format_resolution(captureDevice.activeFormat));
+#ifdef Q_OS_IOS
+    if (!m_service->imageCaptureControl() || !m_service->imageCaptureControl()->stillImageOutput()) {
+        qDebugCamera() << Q_FUNC_INFO << "no still image output";
+        return settings;
+    }
+
+    AVCaptureStillImageOutput *stillImageOutput = m_service->imageCaptureControl()->stillImageOutput();
+    if (stillImageOutput.highResolutionStillImageOutputEnabled)
+        res = qt_device_format_high_resolution(captureDevice.activeFormat);
+#endif
+    if (res.isNull() || !res.isValid()) {
+        qDebugCamera() << Q_FUNC_INFO << "failed to exctract the image resolution";
+        return settings;
+    }
+
+    settings.setResolution(res);
+    settings.setFormat(QImageEncoderSettings::JPEG);
+
+    return settings;
+}
+
+void AVFImageCaptureControl::setImageSettings(const QImageEncoderSettings &settings)
+{
+    if (m_settings == settings)
+        return;
+
+    m_settings = settings;
+    applySettings();
+}
+
+bool AVFImageCaptureControl::applySettings()
+{
+    if (!videoCaptureDeviceIsValid())
+        return false;
+
+    AVFCameraSession *session = m_service->session();
+    if (!session || (session->state() != QCamera::ActiveState
+        && session->state() != QCamera::LoadedState)
+            || !m_service->cameraControl()->captureMode().testFlag(QCamera::CaptureStillImage)) {
+        return false;
+    }
+
+    if (!m_service->imageCaptureControl()
+        || !m_service->imageCaptureControl()->stillImageOutput()) {
+        qDebugCamera() << Q_FUNC_INFO << "no still image output";
+        return false;
+    }
+
+    if (m_settings.format() != QImageEncoderSettings::UnspecifiedFormat && m_settings.format() != QImageEncoderSettings::JPEG) {
+        qDebugCamera() << Q_FUNC_INFO << "unsupported format:" << m_settings.format();
+        return false;
+    }
+
+    QSize res(m_settings.resolution());
+    if (res.isNull()) {
+        qDebugCamera() << Q_FUNC_INFO << "invalid resolution:" << res;
+        return false;
+    }
+
+    if (!res.isValid()) {
+        // Invalid == default value.
+        // Here we could choose the best format available, but
+        // activeFormat is already equal to 'preset high' by default,
+        // which is good enough, otherwise we can end in some format with low framerates.
+        return false;
+    }
+
+    bool activeFormatChanged = false;
+
+    AVCaptureDevice *captureDevice = m_service->session()->videoCaptureDevice();
+    AVCaptureDeviceFormat *match = qt_find_best_resolution_match(captureDevice, res,
+                                                                 m_service->session()->defaultCodec());
+
+    if (!match) {
+        qDebugCamera() << Q_FUNC_INFO << "unsupported resolution:" << res;
+        return false;
+    }
+
+    activeFormatChanged = qt_set_active_format(captureDevice, match, true);
+
+#ifdef Q_OS_IOS
+    AVCaptureStillImageOutput *imageOutput = m_service->imageCaptureControl()->stillImageOutput();
+    if (res == qt_device_format_high_resolution(captureDevice.activeFormat))
+        imageOutput.highResolutionStillImageOutputEnabled = YES;
+    else
+        imageOutput.highResolutionStillImageOutputEnabled = NO;
+#endif
+
+    return activeFormatChanged;
+}
+
+bool AVFImageCaptureControl::videoCaptureDeviceIsValid() const
+{
+    if (!m_service->session() || !m_service->session()->videoCaptureDevice())
+        return false;
+
+    AVCaptureDevice *captureDevice = m_service->session()->videoCaptureDevice();
+    if (!captureDevice.formats || !captureDevice.formats.count)
+        return false;
+
+    return true;
+}
+
 #include "moc_avfimagecapturecontrol_p.cpp"