blob: 4659b76e3ffe668d422341b3d690f0a7922c10a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
TARGET = declarative_audioengine
TARGETPATH = QtAudioEngine
include(../qimportbase.pri)
QT += quick qml multimedia-private
win32: LIBS += -lOpenAL32
unix:!mac: LIBS += -lopenal
mac: LIBS += -framework OpenAL
mac: DEFINES += HEADER_OPENAL_PREFIX
DESTDIR = $$QT.multimedia.imports/$$TARGETPATH
target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INCLUDEPATH += ../../multimedia/audio
HEADERS += \
qdeclarative_attenuationmodel_p.h \
qdeclarative_audioengine_p.h \
qdeclarative_soundinstance_p.h \
qdeclarative_audiocategory_p.h \
qdeclarative_audiolistener_p.h \
qdeclarative_playvariation_p.h \
qdeclarative_audiosample_p.h \
qdeclarative_sound_p.h \
qsoundinstance_p.h \
qaudioengine_p.h \
qsoundsource_p.h \
qsoundbuffer_p.h \
qaudioengine_openal_p.h
SOURCES += \
audioengine.cpp \
qdeclarative_attenuationmodel_p.cpp \
qdeclarative_audioengine_p.cpp \
qdeclarative_soundinstance_p.cpp \
qdeclarative_audiocategory_p.cpp \
qdeclarative_audiolistener_p.cpp \
qdeclarative_playvariation_p.cpp \
qdeclarative_audiosample_p.cpp \
qdeclarative_sound_p.cpp \
qsoundinstance_p.cpp \
qaudioengine_p.cpp \
qsoundsource_openal_p.cpp \
qaudioengine_openal_p.cpp
# plugin.qmltypes is used by Qt Creator for syntax highlighting and the QML code model. It needs
# to be regenerated whenever the QML elements exported by the plugin change. This cannot be done
# automatically at compile time because qmlplugindump does not support some QML features and it may
# not be possible when cross-compiling.
#
# To regenerate run 'make qmltypes' which will update the plugins.qmltypes file in the source
# directory. Then review and commit the changes made to plugins.qmltypes.
#
# This will run the following command:
# qmlplugindump <import name> <import version> <path to import plugin> > plugins.qmltypes
# e.g.:
# qmlplugindump QtAudioEngine 5.0 imports/QtAudioEngine/libdeclarative_audioengine.so > plugins.qmltypes
load(resolve_target)
qmltypes.target = qmltypes
qmltypes.commands = $$[QT_INSTALL_BINS]/qmlplugindump QtAudioEngine 1.0 $$QMAKE_RESOLVED_TARGET > $$PWD/plugins.qmltypes
qmltypes.depends = $$QMAKE_RESOLVED_TARGET
QMAKE_EXTRA_TARGETS += qmltypes
# Tell qmake to create such makefile that qmldir, plugins.qmltypes and target
# (i.e. declarative_audioengine) are all copied to $$[QT_INSTALL_IMPORTS]/QtAudioEngine directory,
qmldir.files += $$PWD/qmldir $$PWD/plugins.qmltypes
qmldir.path += $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INSTALLS += target qmldir
|