summaryrefslogtreecommitdiffstats
path: root/src/multimedia/multimedia.pro
blob: e5334937b4035faab7e9b1a15d4df49b9eb33227 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
TARGET = QtMultimedia
QT = core-private network gui-private

QMAKE_DOCS = $$PWD/doc/qtmultimedia.qdocconf

load(qt_module)

INCLUDEPATH *= .

PRIVATE_HEADERS += \
    qmediacontrol_p.h \
    qmediaobject_p.h \
    qmediapluginloader_p.h \
    qmediaservice_p.h \
    qmediaserviceprovider_p.h \
    qmediaresourcepolicyplugin_p.h \
    qmediaresourcepolicy_p.h \
    qmediaresourceset_p.h

PUBLIC_HEADERS += \
    qmediabindableinterface.h \
    qmediacontrol.h \
    qmediaenumdebug.h \
    qmediametadata.h \
    qmediaobject.h \
    qmediaservice.h \
    qmediaserviceproviderplugin.h \
    qmediatimerange.h \
    qmultimedia.h \
    qtmultimediadefs.h \

SOURCES += \
    qmediabindableinterface.cpp \
    qmediacontrol.cpp \
    qmediametadata.cpp \
    qmediaobject.cpp \
    qmediapluginloader.cpp \
    qmediaservice.cpp \
    qmediaserviceprovider.cpp \
    qmediatimerange.cpp \
    qmediaresourcepolicyplugin_p.cpp \
    qmediaresourcepolicy_p.cpp \
    qmediaresourceset_p.cpp \
    qmultimedia.cpp

include(audio/audio.pri)
include(camera/camera.pri)
include(controls/controls.pri)
include(playback/playback.pri)
include(radio/radio.pri)
include(recording/recording.pri)
include(video/video.pri)

ANDROID_BUNDLED_JAR_DEPENDENCIES = \
    jar/QtMultimedia-bundled.jar:org.qtproject.qt5.android.multimedia.QtMultimediaUtils
ANDROID_JAR_DEPENDENCIES = \
    jar/QtMultimedia.jar:org.qtproject.qt5.android.multimedia.QtMultimediaUtils
ANDROID_LIB_DEPENDENCIES = \
    plugins/mediaservice/libqtmedia_android.so \
    lib/libQt5MultimediaQuick_p.so:Qt5Quick
ANDROID_BUNDLED_FILES += \
    lib/libQt5MultimediaQuick_p.so
ANDROID_PERMISSIONS += \
    android.permission.CAMERA \
    android.permission.RECORD_AUDIO
ANDROID_FEATURES += \
    android.hardware.camera
MODULE_PLUGIN_TYPES = \
    mediaservice \
    audio \
    video/videonode \
    playlistformats

win32: LIBS_PRIVATE += -luuid

HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS