summaryrefslogtreecommitdiffstats
path: root/src/multimediawidgets/multimediawidgets.pro
blob: fe8f6d57354945a992902a88a649d315b63260e7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# distinct from Qt Multimedia
TARGET = QtMultimediaWidgets
QT = core gui multimedia-private widgets-private
qtHaveModule(opengl):!contains(QT_CONFIG, opengles1) {
   QT_PRIVATE += opengl
} else {
   DEFINES += QT_NO_OPENGL
}

QMAKE_DOCS = $$PWD/doc/qtmultimediawidgets.qdocconf

load(qt_module)

PRIVATE_HEADERS += \
    qvideowidget_p.h \
    qpaintervideosurface_p.h \

PUBLIC_HEADERS += \
    qtmultimediawidgetdefs.h \
    qcameraviewfinder.h \
    qgraphicsvideoitem.h \
    qvideowidgetcontrol.h \
    qvideowidget.h

SOURCES += \
    qcameraviewfinder.cpp \
    qpaintervideosurface.cpp \
    qvideowidgetcontrol.cpp \
    qvideowidget.cpp

mac {
    !simulator {
        PRIVATE_HEADERS += qpaintervideosurface_mac_p.h
        OBJECTIVE_SOURCES += qpaintervideosurface_mac.mm
    }
    LIBS += -framework AppKit -framework QuartzCore -framework QTKit
}

maemo6 {
    contains(QT_CONFIG, opengles2) {
        PRIVATE_HEADERS += qeglimagetexturesurface_p.h
        SOURCES += qeglimagetexturesurface.cpp

        SOURCES += qgraphicsvideoitem_maemo6.cpp

        LIBS += -lX11
    } else {
        SOURCES += qgraphicsvideoitem.cpp
    }
}

!maemo* {
    SOURCES += qgraphicsvideoitem.cpp
}

HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS