summaryrefslogtreecommitdiffstats
path: root/src/plugins/gstreamer/gstreamer.pro
blob: 137b61c559a562f7221c3055e3823ce982b73801 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102

load(qt_module)

TARGET = qgstengine
QT += multimedia-private network
CONFIG += no_private_qt_headers_warning

contains(config_test_widgets, yes) {
    QT += widgets multimediawidgets-private
    DEFINES += HAVE_WIDGETS
}

PLUGIN_TYPE=mediaservice

load(qt_plugin)
DESTDIR = $$QT.multimedia.plugins/$${PLUGIN_TYPE}

LIBS += -lqgsttools_p

unix:!maemo*:contains(QT_CONFIG, alsa) {
    DEFINES += HAVE_ALSA
    LIBS += -lasound
}

CONFIG += link_pkgconfig

PKGCONFIG += \
    gstreamer-0.10 \
    gstreamer-base-0.10 \
    gstreamer-interfaces-0.10 \
    gstreamer-audio-0.10 \
    gstreamer-video-0.10 \
    gstreamer-pbutils-0.10

maemo*:PKGCONFIG +=gstreamer-plugins-bad-0.10
contains(config_test_gstreamer_appsrc, yes): PKGCONFIG += gstreamer-app-0.10

contains(config_test_resourcepolicy, yes) {
    DEFINES += HAVE_RESOURCE_POLICY
    PKGCONFIG += libresourceqt1
}

maemo6 {
    HEADERS += camerabuttonlistener_meego.h
    SOURCES += camerabuttonlistener_meego.cpp

    PKGCONFIG += qmsystem2

    isEqual(QT_ARCH,armv6):contains(config_test_widgets, yes) {
        HEADERS += qgstreamergltexturerenderer.h
        SOURCES += qgstreamergltexturerenderer.cpp
        QT += opengl
        LIBS += -lEGL -lgstmeegointerfaces-0.10
    }
}

# Input
HEADERS += \
    qgstreamervideorendererinterface.h \
    qgstreamerserviceplugin.h \
    qgstreameraudioinputendpointselector.h \
    qgstreamervideorenderer.h \
    qgstreamervideoinputdevicecontrol.h \
    gstvideoconnector.h \
    qgstcodecsinfo.h \

SOURCES += \
    qgstreamervideorendererinterface.cpp \
    qgstreamerserviceplugin.cpp \
    qgstreameraudioinputendpointselector.cpp \
    qgstreamervideorenderer.cpp \
    qgstreamervideoinputdevicecontrol.cpp \
    qgstcodecsinfo.cpp \
    gstvideoconnector.c \


contains(config_test_xvideo, yes):contains(config_test_widgets, yes): {
    DEFINES += HAVE_XVIDEO

    LIBS += -lXv -lX11 -lXext

    HEADERS += \
        qgstreamervideooverlay.h \
        qgstreamervideowindow.h \
        qgstreamervideowidget.h \
        qx11videosurface.h \

    SOURCES += \
        qgstreamervideooverlay.cpp \
        qgstreamervideowindow.cpp \
        qgstreamervideowidget.cpp \
        qx11videosurface.cpp \
}
include(mediaplayer/mediaplayer.pri)
include(mediacapture/mediacapture.pri)

contains(config_test_gstreamer_photography, yes) {
    include(camerabin/camerabin.pri)
}

target.path += $$[QT_INSTALL_PLUGINS]/$${PLUGIN_TYPE}
INSTALLS += target