blob: 97a05337935c4b22fedb4c19ec49890a60fc9d9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
TEMPLATE = subdirs
SUBDIRS += multimedia
include($$OUT_PWD/multimedia/qtmultimedia-config.pri)
QT_FOR_CONFIG += multimedia-private
# Everything else depends on multimedia
src_qgsttools.subdir = gsttools
src_qgsttools.depends = multimedia
src_qtmmwidgets.subdir = multimediawidgets
src_qtmmwidgets.depends = multimedia
src_plugins.subdir = plugins
src_plugins.depends = multimedia
qtHaveModule(quick):qtConfig(opengl) {
src_qtmultimediaquicktools.subdir = qtmultimediaquicktools
src_qtmultimediaquicktools.depends = multimedia
src_imports.subdir = imports
src_imports.depends = multimedia src_qtmultimediaquicktools
# For the videonode plugin
src_plugins.depends += src_qtmultimediaquicktools
SUBDIRS += \
src_qtmultimediaquicktools \
src_imports
}
# Optional bits
qtHaveModule(widgets) {
SUBDIRS += src_qtmmwidgets
# If widgets is around, plugins depends on widgets too (imports does not)
src_plugins.depends += src_qtmmwidgets
# same with qgsttools
src_qgsttools.depends += src_qtmmwidgets
}
qtConfig(gstreamer) {
SUBDIRS += src_qgsttools
# If gstreamer is present, then plugins should depend on it
src_plugins.depends += src_qgsttools
}
SUBDIRS += src_plugins
|
