blob: 4b5b37340c2197af0a6ee9952c4479a79232edda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
TEMPLATE = subdirs
SUBDIRS += multimedia
# Everything else depends on multimedia
src_qgsttools.subdir = gsttools
src_qgsttools.depends = multimedia
src_qtmultimediaquicktools.subdir = qtmultimediaquicktools
src_qtmultimediaquicktools.depends = multimedia
src_qtmmwidgets.subdir = multimediawidgets
src_qtmmwidgets.depends = multimedia
src_plugins.subdir = plugins
src_plugins.depends = multimedia
src_imports.subdir = imports
src_imports.depends = multimedia src_qtmultimediaquicktools
SUBDIRS += \
src_qtmultimediaquicktools \
src_imports
# Optional bits
contains(config_test_gstreamer, yes) {
SUBDIRS += src_qgsttools
# If gstreamer is present, then plugins should depend on it
src_plugins.depends += src_qgsttools
}
!isEmpty(QT.widgets.name) {
SUBDIRS += src_qtmmwidgets
# If widgets is around, plugins depends on widgets too (imports does not)
src_plugins.depends += src_qtmmwidgets
}
SUBDIRS += src_plugins
|
