blob: cc53e43a440026a6f35929d68c27967e95ed002d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
defineTest(qtConfLibrary_uacpp) {
input = $$eval($${2}.alias)
prefix = $$eval(config.input.$${input}.prefix)
# The Windows SDK ships its dependencies and locates the libraries outside of lib
win32 {
lessThan(QMAKE_MSC_VER, 1900) {
qtLog("UaCpp SDK requires at least Visual Studio 2015")
return(false)
}
!isEmpty(prefix) {
contains(QMAKE_TARGET.arch, x86_64): archdir = win64
else: archdir = win32
config.input.$${input}.libdir += \
$${prefix}/third-party/$${archdir}/vs2015/openssl/out32dll \
$${prefix}/third-party/$${archdir}/vs2015/libxml2/out32dll
} else {
qtLog("No UACPP_PREFIX specified; relying on user-provided library path.")
}
}
inc = $$eval(config.input.$${input}.incdir)
isEmpty(inc):!isEmpty(prefix): \
inc = $${prefix}/include
!isEmpty(inc) {
config.input.$${input}.incdir += \
$$inc/uabasecpp $$inc/uaclientcpp $$inc/uastack $$inc/uapkicpp
} else {
qtLog("No UACPP_PREFIX and no UACPP_INCDIR specified; relying on global include paths.")
}
!qtConfLibrary_inline($$1, $$2): \
return(false)
return(true)
}
|
