/****************************************************************************
**
** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
** Contact: http://www.qt-project.org/legal
**
** This file is part of the examples of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
**     of its contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 1.0

Item {
    id: main
    anchors.fill: parent

    Image {
        id: background
        anchors.fill: parent
        source: "images/bg.jpg"
    }

    DropShadowEffect {
        id: layer

        property real distance: 0.0

        width: photo.width
        height: photo.height
        sourceItem: photo
        color: "black"
        blur: distance / 10.0
        opacity: 1 - distance / 50.0

        Binding {
            target: layer
            property: "x"
            value: -0.4 * layer.distance
            when: !dragArea.pressed
        }
        Binding {
            target: layer
            property: "y"
            value: 0.9 * layer.distance
            when: !dragArea.pressed
        }

        SequentialAnimation on distance {
            id: animation
            running: true
            loops:  Animation.Infinite

            NumberAnimation { to: 30; duration: 2000 }
            PauseAnimation { duration: 500 }
            NumberAnimation { to: 0; duration: 2000 }
            PauseAnimation { duration: 500 }
        }
    }

    Image {
        id: photo
        anchors.fill: parent
        source: "images/drop_shadow.png"
        smooth: true
    }

    MouseArea {
        id: dragArea
        anchors.fill: parent

        property int startX
        property int startY

        onPressed: {
            startX = mouseX
            startY = mouseY
        }

        onPositionChanged: {
            layer.x += mouseX - startX
            layer.y += mouseY - startY
            startX = mouseX
            startY = mouseY
        }
    }
}