Add tst_material

Tests that the inheritance of theme & accent works as expected. This
is useful for avoiding regressions in the process of introducing a
shared base class for QQuickMaterialStyle and QQuickUniversalStyle.

Change-Id: Ib2eb5922323131fb531344b80dc928a0a07cca90
Reviewed-by: Mitch Curtis <mitch.curtis@theqtcompany.com>

3 files changed, 275 insertions, 0 deletions

diff --git a/tests/auto/material/data/tst_material.qml b/tests/auto/material/data/tst_material.qml
new file mode 100644
index 00000000..7797b8c3
--- /dev/null
+++ b/tests/auto/material/data/tst_material.qml
@@ -0,0 +1,225 @@
+/****************************************************************************
+**
+** Copyright (C) 2015 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the test suite of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.2
+import QtQuick.Window 2.2
+import QtTest 1.0
+import Qt.labs.controls 1.0
+import Qt.labs.controls.material 1.0
+
+TestCase {
+    id: testCase
+    width: 200
+    height: 200
+    visible: true
+    when: windowShown
+    name: "Material"
+
+    Component {
+        id: button
+        Button { }
+    }
+
+    Component {
+        id: styledButton
+        Button {
+            Material.theme: Material.Dark
+            Material.accent: Material.DeepPurple
+        }
+    }
+
+    Component {
+        id: window
+        Window { }
+    }
+
+    Component {
+        id: styledWindow
+        Window {
+            Material.theme: Material.Dark
+            Material.accent: Material.Green
+        }
+    }
+
+    Component {
+        id: loader
+        Loader {
+            active: false
+            sourceComponent: Button { }
+        }
+    }
+
+    Component {
+        id: swipeView
+        SwipeView {
+            Material.theme: Material.Dark
+            Button { }
+        }
+    }
+
+    function test_defaults() {
+        var control = button.createObject(testCase)
+        verify(control)
+        verify(control.Material)
+        compare(control.Material.accent, Material.Teal)
+        compare(control.Material.theme, Material.Light)
+        control.destroy()
+    }
+
+    function test_set() {
+        var control = button.createObject(testCase)
+        verify(control)
+        control.Material.accent = Material.Brown
+        control.Material.theme = Material.Dark
+        compare(control.Material.accent, Material.Brown)
+        compare(control.Material.theme, Material.Dark)
+        control.destroy()
+    }
+
+    function test_reset() {
+        var control = styledButton.createObject(testCase)
+        verify(control)
+        compare(control.Material.accent, Material.DeepPurple)
+        compare(control.Material.theme, Material.Dark)
+        control.Material.accent = undefined
+        control.Material.theme = undefined
+        compare(control.Material.accent, testCase.Material.accent)
+        compare(control.Material.theme, testCase.Material.theme)
+        control.destroy()
+    }
+
+    function test_inheritance_data() {
+        return [
+            { tag: "accent", value1: Material.Amber, value2: Material.Indigo },
+            { tag: "theme", value1: Material.Dark, value2: Material.Light },
+        ]
+    }
+
+    function test_inheritance(data) {
+        var prop = data.tag
+        var parent = button.createObject(testCase)
+        parent.Material[prop] = data.value1
+        compare(parent.Material[prop], data.value1)
+
+        var child1 = button.createObject(parent)
+        compare(child1.Material[prop], data.value1)
+
+        parent.Material[prop] = data.value2
+        compare(parent.Material[prop], data.value2)
+        compare(child1.Material[prop], data.value2)
+
+        var child2 = button.createObject(parent)
+        compare(child2.Material[prop], data.value2)
+
+        child2.Material[prop] = data.value1
+        compare(child2.Material[prop], data.value1)
+        compare(child1.Material[prop], data.value2)
+        compare(parent.Material[prop], data.value2)
+
+        parent.Material[prop] = undefined
+        verify(parent.Material[prop] !== data.value1)
+        verify(parent.Material[prop] !== undefined)
+        compare(child1.Material[prop], parent.Material[prop])
+        verify(child2.Material[prop] !== parent.Material[prop])
+
+        var grandChild1 = button.createObject(child1)
+        var grandChild2 = button.createObject(child2)
+        compare(grandChild1.Material[prop], child1.Material[prop])
+        compare(grandChild2.Material[prop], child2.Material[prop])
+
+        var themelessGrandGrandChild = button.createObject(grandChild1)
+        var grandGrandGrandChild1 = button.createObject(themelessGrandGrandChild)
+        compare(grandGrandGrandChild1.Material[prop], parent.Material[prop])
+
+        child1.Material[prop] = data.value2
+        compare(child1.Material[prop], data.value2)
+        compare(grandChild1.Material[prop], data.value2)
+        compare(grandGrandGrandChild1.Material[prop], data.value2)
+
+        parent.destroy()
+    }
+
+    function test_window() {
+        var parent = window.createObject()
+
+        var control = button.createObject(parent.contentItem)
+        compare(control.Material.accent, parent.Material.accent)
+        compare(control.Material.theme, parent.Material.theme)
+
+        var styledChild = styledWindow.createObject(window)
+        verify(styledChild.Material.accent !== parent.Material.accent)
+        verify(styledChild.Material.theme !== parent.Material.theme)
+
+        var unstyledChild = window.createObject(window)
+        compare(unstyledChild.Material.accent, parent.Material.accent)
+        compare(unstyledChild.Material.theme, parent.Material.theme)
+
+        parent.Material.accent = Material.Cyan
+        compare(control.Material.accent, Material.Cyan)
+        verify(styledChild.Material.accent !== Material.Cyan)
+        // ### TODO: compare(unstyledChild.Material.accent, Material.Cyan)
+
+        parent.destroy()
+    }
+
+    function test_loader() {
+        var control = loader.createObject(testCase)
+        control.Material.accent = Material.Lime
+        control.active = true
+        compare(control.item.Material.accent, Material.Lime)
+        control.Material.accent = Material.Pink
+        compare(control.item.Material.accent, Material.Pink)
+        control.active = false
+        control.Material.accent = Material.Brown
+        control.active = true
+        compare(control.item.Material.accent, Material.Brown)
+        control.destroy()
+    }
+
+    function test_swipeView() {
+        var control = swipeView.createObject(testCase)
+        verify(control)
+        var child = control.itemAt(0)
+        verify(child)
+        compare(control.Material.theme, Material.Dark)
+        compare(child.Material.theme, Material.Dark)
+        control.destroy()
+    }
+}
diff --git a/tests/auto/material/material.pro b/tests/auto/material/material.pro
new file mode 100644
index 00000000..acd16cab
--- /dev/null
+++ b/tests/auto/material/material.pro
@@ -0,0 +1,12 @@
+TEMPLATE = app
+TARGET = tst_material
+CONFIG += qmltestcase
+
+SOURCES += \
+    $$PWD/tst_material.cpp
+
+OTHER_FILES += \
+    $$PWD/data/*
+
+TESTDATA += \
+    $$PWD/data/tst_*
diff --git a/tests/auto/material/tst_material.cpp b/tests/auto/material/tst_material.cpp
new file mode 100644
index 00000000..5db9c12b
--- /dev/null
+++ b/tests/auto/material/tst_material.cpp
@@ -0,0 +1,38 @@
+/****************************************************************************
+**
+** Copyright (C) 2015 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the test suite of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include <QtQuickTest/quicktest.h>
+QUICK_TEST_MAIN(tst_material)