1 files changed, 140 insertions, 0 deletions
diff --git a/examples/quickcontrols2/flatstyle/Flat/Switch.qml b/examples/quickcontrols2/flatstyle/Flat/Switch.qml
new file mode 100644
index 00000000..00b38767
--- /dev/null
+++ b/examples/quickcontrols2/flatstyle/Flat/Switch.qml
@@ -0,0 +1,140 @@
+/****************************************************************************
+**
+** Copyright (C) 2017 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.8
+import QtQuick.Templates 2.1 as T
+import Theme 1.0
+
+T.Switch {
+    id: control
+
+    implicitWidth: indicator.implicitWidth
+    implicitHeight: background.implicitHeight
+
+    background: Rectangle {
+        implicitWidth: 140
+        implicitHeight: Theme.baseSize * 3.8
+        color: Theme.lightGray
+        border.color: Theme.gray
+    }
+
+    leftPadding: 4
+
+    indicator: Rectangle {
+        id: switchHandle
+        implicitWidth: Theme.baseSize * 4.8
+        implicitHeight: Theme.baseSize * 2.6
+        x: control.leftPadding
+        anchors.verticalCenter: parent.verticalCenter
+        radius: Theme.baseSize * 1.3
+        color: Theme.light
+        border.color: Theme.lightGray
+
+        Rectangle {
+            id: rectangle
+
+            width: Theme.baseSize * 2.6
+            height: Theme.baseSize * 2.6
+            radius: Theme.baseSize * 1.3
+            color: Theme.light
+            border.color: Theme.gray
+        }
+
+        states: [
+            State {
+                name: "off"
+                when: !control.checked && !control.down
+            },
+            State {
+                name: "on"
+                when: control.checked && !control.down
+
+                PropertyChanges {
+                    target: switchHandle
+                    color: Theme.mainColor
+                    border.color: Theme.mainColor
+                }
+
+                PropertyChanges {
+                    target: rectangle
+                    x: parent.width - width
+
+                }
+            },
+            State {
+                name: "off_down"
+                when: !control.checked && control.down
+
+                PropertyChanges {
+                    target: rectangle
+                    color: Theme.light
+                }
+
+            },
+            State {
+                name: "on_down"
+                extend: "off_down"
+                when: control.checked && control.down
+
+                PropertyChanges {
+                    target: rectangle
+                    x: parent.width - width
+                    color: Theme.light
+                }
+
+                PropertyChanges {
+                    target: switchHandle
+                    color: Theme.mainColorDarker
+                    border.color: Theme.mainColorDarker
+                }
+            }
+        ]
+    }
+}