1 files changed, 82 insertions, 0 deletions
diff --git a/src/imports/controls/universal/impl/CheckIndicator.qml b/src/imports/controls/universal/impl/CheckIndicator.qml
new file mode 100644
index 00000000..7e8d9327
--- /dev/null
+++ b/src/imports/controls/universal/impl/CheckIndicator.qml
@@ -0,0 +1,82 @@
+/****************************************************************************
+**
+** Copyright (C) 2017 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+import QtQuick.Templates 2.12 as T
+import QtQuick.Controls 2.12
+import QtQuick.Controls.impl 2.12
+import QtQuick.Controls.Universal 2.12
+
+Rectangle {
+    id: indicator
+    implicitWidth: 20
+    implicitHeight: 20
+
+    color: !control.enabled ? "transparent" :
+            control.down && !partiallyChecked ? control.Universal.baseMediumColor :
+            control.checkState === Qt.Checked ? control.Universal.accent : "transparent"
+    border.color: !control.enabled ? control.Universal.baseLowColor :
+                   control.down ? control.Universal.baseMediumColor :
+                   control.checked ? control.Universal.accent : control.Universal.baseMediumHighColor
+    border.width: 2 // CheckBoxBorderThemeThickness
+
+    property Item control
+    readonly property bool partiallyChecked: control.checkState === Qt.PartiallyChecked
+
+    ColorImage {
+        x: (parent.width - width) / 2
+        y: (parent.height - height) / 2
+
+        visible: indicator.control.checkState === Qt.Checked
+        color: !indicator.control.enabled ? indicator.control.Universal.baseLowColor : indicator.control.Universal.chromeWhiteColor
+        source: "qrc:/qt-project.org/imports/QtQuick/Controls/Universal/images/checkmark.png"
+    }
+
+    Rectangle {
+        x: (parent.width - width) / 2
+        y: (parent.height - height) / 2
+        width: indicator.partiallyChecked ? parent.width / 2 : parent.width
+        height: indicator.partiallyChecked ? parent.height / 2 : parent.height
+
+        visible: !indicator.control.pressed && indicator.control.hovered || indicator.partiallyChecked
+        color: !indicator.partiallyChecked ? "transparent" :
+               !indicator.control.enabled ? indicator.control.Universal.baseLowColor :
+                indicator.control.down ? indicator.control.Universal.baseMediumColor :
+                indicator.control.hovered ? indicator.control.Universal.baseHighColor : indicator.control.Universal.baseMediumHighColor
+        border.width: indicator.partiallyChecked ? 0 : 2 // CheckBoxBorderThemeThickness
+        border.color: indicator.control.Universal.baseMediumLowColor
+    }
+}