1 files changed, 192 insertions, 1 deletions
diff --git a/tests/auto/controls/data/tst_abstractbutton.qml b/tests/auto/controls/data/tst_abstractbutton.qml
index bddb952f..7579d410 100644
--- a/tests/auto/controls/data/tst_abstractbutton.qml
+++ b/tests/auto/controls/data/tst_abstractbutton.qml
@@ -50,7 +50,7 @@
 
 import QtQuick 2.2
 import QtTest 1.0
-import QtQuick.Controls 2.2
+import QtQuick.Controls 2.3
 
 TestCase {
     id: testCase
@@ -71,6 +71,11 @@ TestCase {
     }
 
     Component {
+        id: action
+        Action { }
+    }
+
+    Component {
         id: signalSpy
         SignalSpy { }
     }
@@ -162,4 +167,190 @@ TestCase {
         keyRelease(data.key)
         compare(container.lastKeyRelease, data.result)
     }
+
+    function test_icon() {
+        var control = createTemporaryObject(button, testCase)
+        verify(control)
+        compare(control.icon.name, "")
+        compare(control.icon.source, "")
+        compare(control.icon.width, 0)
+        compare(control.icon.height, 0)
+        compare(control.icon.color, "#00000000")
+
+        var iconSpy = signalSpy.createObject(control, { target: control, signalName: "iconChanged"} )
+        verify(iconSpy.valid)
+
+        control.icon.name = "test-name"
+        compare(control.icon.name, "test-name")
+        compare(iconSpy.count, 1)
+
+        control.icon.source = "qrc:/test-source"
+        compare(control.icon.source, "qrc:/test-source")
+        compare(iconSpy.count, 2)
+
+        control.icon.width = 32
+        compare(control.icon.width, 32)
+        compare(iconSpy.count, 3)
+
+        control.icon.height = 32
+        compare(control.icon.height, 32)
+        compare(iconSpy.count, 4)
+
+        control.icon.color = "#ff0000"
+        compare(control.icon.color, "#ff0000")
+        compare(iconSpy.count, 5)
+    }
+
+    Component {
+        id: actionButton
+        AbstractButton {
+            action: Action {
+                text: "Default"
+                icon.name: "default"
+                icon.source: "qrc:/icons/default.png"
+                checkable: true
+                checked: true
+                enabled: false
+            }
+        }
+    }
+
+    function test_action() {
+        var control = createTemporaryObject(actionButton, testCase)
+        verify(control)
+
+        // initial values
+        compare(control.text, "Default")
+        compare(control.icon.name, "default")
+        compare(control.icon.source, "qrc:/icons/default.png")
+        compare(control.checkable, true)
+        compare(control.checked, true)
+        compare(control.enabled, false)
+
+        // changes via action
+        control.action.text = "Action"
+        control.action.icon.name = "action"
+        control.action.icon.source = "qrc:/icons/action.png"
+        control.action.checkable = false
+        control.action.checked = false
+        control.action.enabled = true
+        compare(control.text, "Action") // propagates
+        compare(control.icon.name, "action") // propagates
+        compare(control.icon.source, "qrc:/icons/action.png") // propagates
+        compare(control.checkable, false) // propagates
+        compare(control.checked, false) // propagates
+        compare(control.enabled, true) // propagates
+
+        // changes via button
+        control.text = "Button"
+        control.icon.name = "button"
+        control.icon.source = "qrc:/icons/button.png"
+        control.checkable = true
+        control.checked = true
+        control.enabled = false
+        compare(control.text, "Button")
+        compare(control.icon.name, "button")
+        compare(control.icon.source, "qrc:/icons/button.png")
+        compare(control.checkable, true)
+        compare(control.checked, true)
+        compare(control.enabled, false)
+        compare(control.action.text, "Action") // does NOT propagate
+        compare(control.action.icon.name, "action") // does NOT propagate
+        compare(control.action.icon.source, "qrc:/icons/action.png") // does NOT propagate
+        compare(control.action.checkable, true) // propagates
+        compare(control.action.checked, true) // propagates
+        compare(control.action.enabled, true) // does NOT propagate
+    }
+
+    function test_trigger_data() {
+        return [
+            {tag: "click", click: true, button: true, action: true, clicked: true, triggered: true},
+            {tag: "click disabled button", click: true, button: false, action: true, clicked: false, triggered: false},
+            {tag: "click disabled action", click: true, button: true, action: false, clicked: true, triggered: false},
+            {tag: "trigger", trigger: true, button: true, action: true, clicked: true, triggered: true},
+            {tag: "trigger disabled button", trigger: true, button: false, action: true, clicked: false, triggered: true},
+            {tag: "trigger disabled action", trigger: true, button: true, action: false, clicked: false, triggered: false}
+        ]
+    }
+
+    function test_trigger(data) {
+        var control = createTemporaryObject(actionButton, testCase, {"enabled": data.button, "action.enabled": data.action})
+        verify(control)
+
+        compare(control.enabled, data.button)
+        compare(control.action.enabled, data.action)
+
+        var buttonSpy = signalSpy.createObject(control, {target: control, signalName: "clicked"})
+        verify(buttonSpy.valid)
+
+        var actionSpy = signalSpy.createObject(control, {target: control.action, signalName: "triggered"})
+        verify(actionSpy.valid)
+
+        if (data.click)
+            mouseClick(control)
+        else if (data.trigger)
+            control.action.trigger()
+
+        compare(buttonSpy.count, data.clicked ? 1 : 0)
+        compare(actionSpy.count, data.triggered ? 1 : 0)
+    }
+
+    function test_mnemonic() {
+        if (Qt.platform.os === "osx" || Qt.platform.os === "macos")
+            skip("Mnemonics are not used on macOS")
+
+        var control = createTemporaryObject(button, testCase)
+        verify(control)
+
+        control.text = "&Hello"
+        compare(control.text, "Hello") // ### TODO: visualize mnemonics
+
+        var clickSpy = signalSpy.createObject(control, {target: control, signalName: "clicked"})
+        verify(clickSpy.valid)
+
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 1)
+
+        control.visible = false
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 1)
+
+        control.visible = true
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 2)
+
+        control.text = "Te&st"
+        compare(control.text, "Test") // ### TODO: visualize mnemonics
+
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 2)
+
+        keyClick(Qt.Key_S, Qt.AltModifier)
+        compare(clickSpy.count, 3)
+
+        control.visible = false
+        control.text = "&Hidden"
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 3)
+
+        control.visible = true
+        keyClick(Qt.Key_H, Qt.AltModifier)
+        compare(clickSpy.count, 4)
+
+        control.action = action.createObject(control, {text: "&Action"})
+
+        var actionSpy = signalSpy.createObject(control, {target: control.action, signalName: "triggered"})
+        verify(actionSpy.valid)
+
+        keyClick(Qt.Key_A, Qt.AltModifier)
+        compare(actionSpy.count, 1)
+        compare(clickSpy.count, 5)
+
+        // ungrab on destruction (don't crash)
+        control.Component.onDestruction.connect(function() { control = null })
+        control.destroy()
+        wait(0)
+        verify(!control)
+        keyClick(Qt.Key_H, Qt.AltModifier)
+    }
 }