From 5246dd2de211ffb81313a5c29ae7894545a28c43 Mon Sep 17 00:00:00 2001
From: Mitch Curtis <mitch.curtis@qt.io>
Date: Fri, 27 Mar 2020 11:17:35 +0100
Subject: Register C++ types declaratively

Adapt to the new way of registering C++ types. The types need to be
seen at compile time so that code can be generated that invokes them.

This patch:

- Adds QML_* macros where applicable.
- Adapts the build system files to the new way of registering modules.
- Splits up the QtQuick.Controls[.*].impl files into their own plugins,
  as we can only register one QML module per .pro file.
- Removes C++ type registration calls in every plugin.
- Moves private types from src/quickcontrols2/quickcontrols2.pro
  to src/quickcontrols2/impl/quickcontrols2-impl.pro. Some of these
  types need to be exposed to QML, but quickcontrols2.pro is already in
  use to declare the QtQuick.Controls import (and also provides the
  public C++ QQuickStyle API), and the new QML_IMPORT_NAME/VERSION
  syntax only allows one module per project. As some of the types that
  need to be exposed to QML are also referenced by some C++ code (e.g.
  tests, etc.), we just move all of the private types to the new
  library.

Follow-up patches will register the QML types declaratively.

Task-number: QTBUG-82922
Change-Id: Iaf9ee106237d61701d57a8896f3822304c8151a6
Reviewed-by: Ulf Hermann <ulf.hermann@qt.io>
---
 src/imports/controls/imagine/impl/imagine-impl.pro | 39 ++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 src/imports/controls/imagine/impl/imagine-impl.pro

(limited to 'src/imports/controls/imagine/impl/imagine-impl.pro')

diff --git a/src/imports/controls/imagine/impl/imagine-impl.pro b/src/imports/controls/imagine/impl/imagine-impl.pro
new file mode 100644
index 00000000..cb0f7043
--- /dev/null
+++ b/src/imports/controls/imagine/impl/imagine-impl.pro
@@ -0,0 +1,39 @@
+TARGET = qtquickcontrols2imaginestyleimplplugin
+TARGETPATH = QtQuick/Controls.2/Imagine/impl
+
+QML_IMPORT_NAME = QtQuick.Controls.Imagine.impl
+QML_IMPORT_VERSION = 2.$$QT_MINOR_VERSION
+
+QT += qml quick
+QT_PRIVATE += core-private gui qml-private quick-private quicktemplates2-private quickcontrols2impl-private
+QT_FOR_CONFIG = quickcontrols2-private
+
+DEFINES += QT_NO_CAST_TO_ASCII QT_NO_CAST_FROM_ASCII
+
+QML_FILES += \
+    $$PWD/OpacityMask.qml
+
+OTHER_FILES += \
+    qmldir \
+    $$QML_FILES
+
+HEADERS += \
+    $$PWD/qquickimageselector_p.h \
+    $$PWD/qquickninepatchimage_p.h
+
+SOURCES += \
+    $$PWD/qquickimageselector.cpp \
+    $$PWD/qquickninepatchimage.cpp \
+    $$PWD/qtquickcontrols2imaginestyleimplplugin.cpp
+
+qtquickcontrols2imaginestyleimpl.prefix = qt-project.org/imports/QtQuick/Controls/Imagine/impl
+qtquickcontrols2imaginestyleimpl.files += \
+    $$files($$PWD/shaders/OpacityMask.frag) \
+    $$files($$PWD/shaders/+glslcore/OpacityMask.frag) \
+    $$files($$PWD/shaders/+qsb/OpacityMask.frag)
+RESOURCES += qtquickcontrols2imaginestyleimpl
+
+CONFIG += qmltypes install_qmltypes no_cxx_module builtin_resources qtquickcompiler
+load(qml_plugin)
+
+requires(qtConfig(quickcontrols2-imagine))
-- 
cgit v1.2.3