From bf55d2b1659290753641ee862f814ab8781cfa94 Mon Sep 17 00:00:00 2001
From: J-P Nurmi <jpnurmi@theqtcompany.com>
Date: Sat, 17 Oct 2015 17:34:31 +0200
Subject: Add Universal style

https://dev.windows.com/design

Change-Id: I1d8c633ae246724649a6ed71b300a56ba9572405
Reviewed-by: Mitch Curtis <mitch.curtis@theqtcompany.com>
---
 src/imports/controls/universal/Switch.qml | 111 ++++++++++++++++++++++++++++++
 1 file changed, 111 insertions(+)
 create mode 100644 src/imports/controls/universal/Switch.qml

(limited to 'src/imports/controls/universal/Switch.qml')

diff --git a/src/imports/controls/universal/Switch.qml b/src/imports/controls/universal/Switch.qml
new file mode 100644
index 00000000..5a28b031
--- /dev/null
+++ b/src/imports/controls/universal/Switch.qml
@@ -0,0 +1,111 @@
+/****************************************************************************
+**
+** Copyright (C) 2015 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the Qt Labs Controls module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.6
+import Qt.labs.templates 1.0 as T
+import Qt.labs.controls.universal 1.0
+
+T.Switch {
+    id: control
+
+    implicitWidth: Math.max(background ? background.implicitWidth : 0,
+                            (label ? label.implicitWidth : 0) +
+                            (indicator ? indicator.implicitWidth : 0) +
+                            (label && indicator ? spacing : 0) + leftPadding + rightPadding)
+    implicitHeight: Math.max(background ? background.implicitHeight : 0,
+                             Math.max(label ? label.implicitHeight : 0,
+                                      indicator ? indicator.implicitHeight : 0) + topPadding + bottomPadding)
+
+    padding: 5
+    spacing: 8
+
+    font.pixelSize: Universal.fontSize
+    font.family: Universal.fontFamily
+
+    //! [indicator]
+    indicator: Rectangle {
+        implicitWidth: 44
+        implicitHeight: 20
+        x: text ? (control.mirrored ? control.width - width - control.rightPadding : control.leftPadding) : control.leftPadding + (control.availableWidth - width) / 2
+        y: control.topPadding + (control.availableHeight - height) / 2
+
+        radius: 10
+        color: !control.enabled ? "transparent" :
+                control.pressed ? control.Universal.baseMediumColor :
+                control.checked ? control.Universal.accentColor : "transparent"
+        border.color: !control.enabled ? control.Universal.baseLowColor :
+                       control.checked && !control.pressed ? control.Universal.accentColor : control.Universal.baseMediumColor
+        border.width: 2
+
+        Rectangle {
+            width: 10
+            height: 10
+            radius: 5
+
+            color: !control.enabled ? control.Universal.baseLowColor :
+                    control.pressed || control.checked ? control.Universal.chromeWhiteColor : control.Universal.baseMediumHighColor
+
+            x: Math.max(5, Math.min(parent.width - width - 5,
+                                    control.visualPosition * parent.width - (width / 2)))
+            y: (parent.height - height) / 2
+
+            Behavior on x {
+                enabled: !control.pressed
+                SmoothedAnimation { velocity: 200 }
+            }
+        }
+    }
+    //! [indicator]
+
+    //! [label]
+    label: Text {
+        x: control.mirrored ? control.leftPadding : (indicator.x + indicator.width + control.spacing)
+        y: control.topPadding
+        width: control.availableWidth - indicator.width - control.spacing
+        height: control.availableHeight
+
+        text: control.text
+        font: control.font
+        elide: Text.ElideRight
+        visible: control.text
+        horizontalAlignment: Text.AlignLeft
+        verticalAlignment: Text.AlignVCenter
+        renderType: Text.NativeRendering
+
+        color: !control.enabled ? control.Universal.baseLowColor : control.Universal.baseHighColor
+    }
+    //! [label]
+}
-- 
cgit v1.2.3