blob: 05329e4b3c2d18fe60502f7119c4e1c9f28e32b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
|
/****************************************************************************
**
** Copyright (C) 2021 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:COMM$
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** $QT_END_LICENSE$
**
**
**
**
**
**
**
**
**
**
**
**
**
**
**
**
****************************************************************************/
import QtQuick 2.12
import QtQuick.Templates 2.12 as T
import QtQuick.Controls.Material 2.12
import QtQuick.Controls.Material.impl 2.12
T.SpinBox {
id: control
implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
contentItem.implicitWidth +
up.implicitIndicatorWidth +
down.implicitIndicatorWidth)
implicitHeight: Math.max(implicitContentHeight + topPadding + bottomPadding,
implicitBackgroundHeight,
up.implicitIndicatorHeight,
down.implicitIndicatorHeight)
spacing: 6
topPadding: 8
bottomPadding: 16
leftPadding: (control.mirrored ? (up.indicator ? up.indicator.width : 0) : (down.indicator ? down.indicator.width : 0))
rightPadding: (control.mirrored ? (down.indicator ? down.indicator.width : 0) : (up.indicator ? up.indicator.width : 0))
validator: IntValidator {
locale: control.locale.name
bottom: Math.min(control.from, control.to)
top: Math.max(control.from, control.to)
}
contentItem: TextInput {
text: control.displayText
font: control.font
color: enabled ? control.Material.foreground : control.Material.hintTextColor
selectionColor: control.Material.textSelectionColor
selectedTextColor: control.Material.foreground
horizontalAlignment: Qt.AlignHCenter
verticalAlignment: Qt.AlignVCenter
cursorDelegate: CursorDelegate { }
readOnly: !control.editable
validator: control.validator
inputMethodHints: control.inputMethodHints
}
up.indicator: Item {
x: control.mirrored ? 0 : parent.width - width
implicitWidth: control.Material.touchTarget
implicitHeight: control.Material.touchTarget
height: parent.height
width: height
Ripple {
clipRadius: 2
x: control.spacing
y: control.spacing
width: parent.width - 2 * control.spacing
height: parent.height - 2 * control.spacing
pressed: control.up.pressed
active: control.up.pressed || control.up.hovered || control.visualFocus
color: control.Material.rippleColor
}
Rectangle {
x: (parent.width - width) / 2
y: (parent.height - height) / 2
width: Math.min(parent.width / 3, parent.height / 3)
height: 2
color: enabled ? control.Material.foreground : control.Material.spinBoxDisabledIconColor
}
Rectangle {
x: (parent.width - width) / 2
y: (parent.height - height) / 2
width: 2
height: Math.min(parent.width / 3, parent.height / 3)
color: enabled ? control.Material.foreground : control.Material.spinBoxDisabledIconColor
}
}
down.indicator: Item {
x: control.mirrored ? parent.width - width : 0
implicitWidth: control.Material.touchTarget
implicitHeight: control.Material.touchTarget
height: parent.height
width: height
Ripple {
clipRadius: 2
x: control.spacing
y: control.spacing
width: parent.width - 2 * control.spacing
height: parent.height - 2 * control.spacing
pressed: control.down.pressed
active: control.down.pressed || control.down.hovered || control.visualFocus
color: control.Material.rippleColor
}
Rectangle {
x: (parent.width - width) / 2
y: (parent.height - height) / 2
width: parent.width / 3
height: 2
color: enabled ? control.Material.foreground : control.Material.spinBoxDisabledIconColor
}
}
background: Item {
implicitWidth: 192
implicitHeight: control.Material.touchTarget
Rectangle {
x: parent.width / 2 - width / 2
y: parent.y + parent.height - height - control.bottomPadding / 2
width: control.availableWidth
height: control.activeFocus ? 2 : 1
color: control.activeFocus ? control.Material.accentColor : control.Material.hintTextColor
}
}
}
|