summaryrefslogtreecommitdiffstats
path: root/src/plugins/sensors/sensors.pro
blob: 302bd96e7965a5bcd4bbb709ef18f9f3ad7d16aa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
TEMPLATE = subdirs

blackberry {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = blackberry generic
}

android {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = android generic
}

sensorfw {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = sensorfw generic
}

ios {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = ios generic
}

winrt {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = winrt generic
}

tizen {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = tizen generic
}

qtHaveModule(simulator) {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = simulator generic
}

linux {
    isEmpty(SENSORS_PLUGINS): SENSORS_PLUGINS = linux generic
}

contains(SENSORS_PLUGINS, dummy):SUBDIRS += dummy
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, generic):SUBDIRS += generic
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, simulator):qtHaveModule(simulator):SUBDIRS += simulator
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, blackberry):blackberry:SUBDIRS += blackberry
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, linux):linux:SUBDIRS += linux
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, android):android:SUBDIRS += android
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, sensorfw):sensorfw:SUBDIRS += sensorfw
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, ios):ios:SUBDIRS += ios
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, winrt):winrt:SUBDIRS += winrt
isEmpty(SENSORS_PLUGINS)|contains(SENSORS_PLUGINS, tizen):tizen:config_tizensensor_header:SUBDIRS += tizen