qtserialbus.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

requires(!wince)
requires(!winrt) # enforced by qtserialport dependency
requires(!ios)   # enforced by qtserialport dependency

lessThan(QT_MAJOR_VERSION, 5) {
    message("Cannot build current QtSerialBus sources with Qt version $${QT_VERSION}.")
}

load(configure)
qtCompileTest(socketcan)
qtCompileTest(socketcan_fd)

# Check we have a platform libmodbus in case we prefer the platform version.
qtCompileTest(libmodbus_systemlib)

qtCompileTest(libmodbus_accept4)
qtCompileTest(libmodbus_byteswap)
qtCompileTest(libmodbus_rs485)
qtCompileTest(libmodbus_strlcpy)
qtCompileTest(libmodbus_tiocmrts)
load(qt_parts)

linux {
    !config_socketcan:warning("You need linux/can.h and linux/can/raw.h linux headers for socketCAN support, disabling it")
    !config_socketcan_fd:warning("Newer kernel needed for flexible data-rate frame support 'canfd_frame'")
}

config_libmodbus_systemlib {
    message("Using platform's libmodbus")
} else {
    message("Using internal libmodbus")
}