1 files changed, 71 insertions, 0 deletions
diff --git a/src/assistant/lib/lib.pro b/src/assistant/lib/lib.pro
new file mode 100644
index 000000000..03821b2a7
--- /dev/null
+++ b/src/assistant/lib/lib.pro
@@ -0,0 +1,71 @@
+QT += sql \
+    xml \
+    network
+TEMPLATE = lib
+TARGET = QtHelp
+DEFINES += QHELP_LIB \
+    QT_CLUCENE_SUPPORT
+CONFIG += qt \
+    warn_on
+include(../../../src/qbase.pri)
+QMAKE_TARGET_PRODUCT = Help
+QMAKE_TARGET_DESCRIPTION = Help \
+    application \
+    framework.
+DEFINES -= QT_ASCII_CAST_WARNINGS
+qclucene = QtCLucene$${QT_LIBINFIX}
+if(!debug_and_release|build_pass):CONFIG(debug, debug|release) { 
+    mac:qclucene = $${qclucene}_debug
+    win32:qclucene = $${qclucene}d
+}
+linux-lsb-g++:LIBS_PRIVATE += --lsb-shared-libs=$$qclucene
+unix|win32-g++*:QMAKE_PKGCONFIG_REQUIRES += QtNetwork \
+    QtSql \
+    QtXml
+LIBS_PRIVATE += -l$$qclucene
+RESOURCES += helpsystem.qrc
+SOURCES += qhelpenginecore.cpp \
+    qhelpengine.cpp \
+    qhelpdbreader.cpp \
+    qhelpcontentwidget.cpp \
+    qhelpindexwidget.cpp \
+    qhelpgenerator.cpp \
+    qhelpdatainterface.cpp \
+    qhelpprojectdata.cpp \
+    qhelpcollectionhandler.cpp \
+    qhelpsearchengine.cpp \
+    qhelpsearchquerywidget.cpp \
+    qhelpsearchresultwidget.cpp \
+    qhelpsearchindex_default.cpp \
+    qhelpsearchindexwriter_default.cpp \
+    qhelpsearchindexreader_default.cpp \
+    qhelpsearchindexreader.cpp \
+    qclucenefieldnames.cpp \
+    qhelp_global.cpp
+
+# access to clucene
+SOURCES += qhelpsearchindexwriter_clucene.cpp \
+    qhelpsearchindexreader_clucene.cpp
+HEADERS += qhelpenginecore.h \
+    qhelpengine.h \
+    qhelpengine_p.h \
+    qhelp_global.h \
+    qhelpdbreader_p.h \
+    qhelpcontentwidget.h \
+    qhelpindexwidget.h \
+    qhelpgenerator_p.h \
+    qhelpdatainterface_p.h \
+    qhelpprojectdata_p.h \
+    qhelpcollectionhandler_p.h \
+    qhelpsearchengine.h \
+    qhelpsearchquerywidget.h \
+    qhelpsearchresultwidget.h \
+    qhelpsearchindex_default_p.h \
+    qhelpsearchindexwriter_default_p.h \
+    qhelpsearchindexreader_default_p.h \
+    qhelpsearchindexreader_p.h \
+    qclucenefieldnames_p.h
+
+# access to clucene
+HEADERS += qhelpsearchindexwriter_clucene_p.h \
+    qhelpsearchindexreader_clucene_p.h