1 files changed, 90 insertions, 0 deletions
diff --git a/src/designer/src/designer/designer.pro b/src/designer/src/designer/designer.pro
new file mode 100644
index 000000000..8564e96cb
--- /dev/null
+++ b/src/designer/src/designer/designer.pro
@@ -0,0 +1,90 @@
+
+DESTDIR = ../../../../bin
+QT += xml network
+contains(QT_CONFIG, script): QT += script
+build_all:!build_pass {
+    CONFIG -= build_all
+    CONFIG += release
+}
+
+INCLUDEPATH += \
+    ../lib/sdk \
+    ../lib/extension \
+    ../lib/shared \
+    ../lib/uilib \
+    extra
+
+QMAKE_LIBDIR += ../../lib ../../../../lib
+LIBS += -lQtDesignerComponents -lQtDesigner
+
+RESOURCES += designer.qrc
+
+contains(CONFIG, static) {
+    DEFINES += QT_DESIGNER_STATIC
+}
+
+TARGET = designer
+
+include(../../../shared/fontpanel/fontpanel.pri)
+include(../../../shared/qttoolbardialog/qttoolbardialog.pri)
+
+HEADERS += \
+    qdesigner.h \
+    qdesigner_toolwindow.h \
+    qdesigner_formwindow.h \
+    qdesigner_workbench.h \
+    qdesigner_settings.h \
+    qdesigner_actions.h \
+    qdesigner_server.h \
+    qdesigner_appearanceoptions.h \
+    saveformastemplate.h \
+    newform.h \
+    versiondialog.h \
+    designer_enums.h \
+    appfontdialog.h \
+    preferencesdialog.h \
+    assistantclient.h \
+    mainwindow.h
+
+SOURCES += main.cpp \
+    qdesigner.cpp \
+    qdesigner_toolwindow.cpp \
+    qdesigner_formwindow.cpp \
+    qdesigner_workbench.cpp \
+    qdesigner_settings.cpp \
+    qdesigner_server.cpp \
+    qdesigner_actions.cpp \
+    qdesigner_appearanceoptions.cpp \
+    saveformastemplate.cpp \
+    newform.cpp \
+    versiondialog.cpp \
+    appfontdialog.cpp \
+    preferencesdialog.cpp \
+    assistantclient.cpp \
+    mainwindow.cpp
+
+PRECOMPILED_HEADER=qdesigner_pch.h
+
+FORMS += saveformastemplate.ui \
+    preferencesdialog.ui \
+    qdesigner_appearanceoptions.ui
+
+win32 {
+   RC_FILE      = designer.rc
+}
+
+mac {
+    ICON = designer.icns
+    QMAKE_INFO_PLIST = Info_mac.plist
+    TARGET = Designer
+    FILETYPES.files = uifile.icns
+    FILETYPES.path = Contents/Resources
+    QMAKE_BUNDLE_DATA += FILETYPES
+}
+
+target.path=$$[QT_INSTALL_BINS]
+INSTALLS += target
+
+include(../sharedcomponents.pri)
+
+unix:!mac:LIBS += -lm