blob: d083896c31c358c9c231e03d56b9fc3ec8500b67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
QT += core-private gui-private widgets uitools-private printsupport
DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII
include(../shared/formats.pri)
QMAKE_DOCS = $$PWD/doc/qtlinguist.qdocconf
DEFINES += QFORMINTERNAL_NAMESPACE
SOURCES += \
batchtranslationdialog.cpp \
errorsview.cpp \
finddialog.cpp \
formpreviewview.cpp \
globals.cpp \
main.cpp \
mainwindow.cpp \
messageeditor.cpp \
messageeditorwidgets.cpp \
messagehighlighter.cpp \
messagemodel.cpp \
phrasebookbox.cpp \
phrase.cpp \
phrasemodel.cpp \
phraseview.cpp \
printout.cpp \
recentfiles.cpp \
sourcecodeview.cpp \
statistics.cpp \
translatedialog.cpp \
translationsettingsdialog.cpp \
../shared/simtexth.cpp
HEADERS += \
batchtranslationdialog.h \
errorsview.h \
finddialog.h \
formpreviewview.h \
globals.h \
mainwindow.h \
messageeditor.h \
messageeditorwidgets.h \
messagehighlighter.h \
messagemodel.h \
phrasebookbox.h \
phrase.h \
phrasemodel.h \
phraseview.h \
printout.h \
recentfiles.h \
sourcecodeview.h \
statistics.h \
translatedialog.h \
translationsettingsdialog.h \
../shared/simtexth.h
contains(QT_PRODUCT, OpenSource.*):DEFINES *= QT_OPENSOURCE
DEFINES += QT_KEYWORDS
TARGET = linguist
QMAKE_TARGET_DESCRIPTION = Qt Linguist
win32 {
RC_ICONS = linguist.ico
VERSION = $${QT_VERSION}.0
} else {
VERSION = $${QT_VERSION}
}
mac {
static:CONFIG -= global_init_link_order
ICON = linguist.icns
TARGET = Linguist
QMAKE_INFO_PLIST=Info_mac.plist
}
PROJECTNAME = Qt \
Linguist
phrasebooks.path = $$[QT_INSTALL_DATA]/phrasebooks
# ## will this work on windows?
phrasebooks.files = $$PWD/../phrasebooks/*
INSTALLS += phrasebooks
FORMS += statistics.ui \
phrasebookbox.ui \
batchtranslation.ui \
translatedialog.ui \
mainwindow.ui \
translationsettings.ui \
finddialog.ui
RESOURCES += linguist.qrc
load(qt_app)
|