blob: c6174e40175443100c5f91a6d745072bb7703455 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
TEMPLATE = subdirs
!contains(QT_CONFIG, no-gui) {
no-png {
message("Some graphics-related tools are unavailable without PNG support")
} else {
symbian {
SUBDIRS = designer
} else:wince* {
SUBDIRS = qtestlib designer
} else {
SUBDIRS = assistant \
pixeltool \
porting \
qtestlib \
qttracereplay
contains(QT_EDITION, Console) {
SUBDIRS += designer/src/uitools # Linguist depends on this
} else {
SUBDIRS += designer
}
}
unix:!symbian:!mac:!embedded:!qpa:SUBDIRS += qtconfig
win32:!wince*:SUBDIRS += activeqt
}
}
!wince*:!symbian:SUBDIRS += linguist
mac {
SUBDIRS += macdeployqt
}
embedded:SUBDIRS += kmap2qmap
contains(QT_CONFIG, dbus):SUBDIRS += qdbus
# We don't need these command line utilities on embedded platforms.
embedded: SUBDIRS += makeqpf
!wince*:!cross_compile:SUBDIRS += qdoc3
CONFIG+=ordered
QTDIR_build:REQUIRES = "contains(QT_CONFIG, full-config)"
!win32:!embedded:!mac:!symbian:CONFIG += x11
x11:contains(QT_CONFIG, opengles2):contains(QT_CONFIG, egl):SUBDIRS += qmeegographicssystemhelper
|
