blob: 69bea13c2245614329441b5117d09fcb927149cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
TARGET = qtvirtualkeyboard_pinyin
QT += qml virtualkeyboard
HEADERS += \
pinyindecoderservice_p.h \
pinyininputmethod_p.h \
pinyinplugin.h
SOURCES += \
pinyindecoderservice.cpp \
pinyininputmethod.cpp \
pinyinplugin.cpp
OTHER_FILES += \
pinyin.json
include(../../../config.pri)
LAYOUT_FILES += \
$$LAYOUTS_BASE/content/layouts/zh_CN/dialpad.fallback \
$$LAYOUTS_BASE/content/layouts/zh_CN/digits.fallback \
$$LAYOUTS_BASE/content/layouts/zh_CN/main.qml \
$$LAYOUTS_BASE/content/layouts/zh_CN/numbers.fallback \
$$LAYOUTS_BASE/content/layouts/zh_CN/symbols.qml
OTHER_FILES += \
$$LAYOUT_FILES
layouts.files = $$LAYOUT_FILES
layouts.base = $$LAYOUTS_BASE
layouts.prefix = $$LAYOUTS_PREFIX
RESOURCES += layouts
QMAKE_USE += pinyin
!no-bundle-pinyin {
PINYIN_FILES += ../3rdparty/pinyin/data/dict_pinyin.dat
pinyin.files = $$PINYIN_FILES
pinyin.base = $$PWD/..
pinyin.prefix = /QtQuick/VirtualKeyboard
RESOURCES += pinyin
} else {
pinyin_data.files = $$PWD/../3rdparty/pinyin/data/dict_pinyin.dat
pinyin_data.path = $$DATAPATH/pinyin
INSTALLS += pinyin_data
!prefix_build: COPIES += pinyin_data
}
win32 {
QMAKE_TARGET_PRODUCT = "Qt Virtual Keyboard Pinyin (Qt $$QT_VERSION)"
QMAKE_TARGET_DESCRIPTION = "Virtual Keyboard Extension for Qt."
}
PLUGIN_TYPE = virtualkeyboard
PLUGIN_CLASS_NAME = PinyinPlugin
load(qt_plugin)
|
