blob: d92696f151887d9b0852c4292a7af6207b0bf9ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
TARGET = qtvirtualkeyboard_tcime
QT += qml virtualkeyboard
HEADERS += \
tcinputmethod_p.h \
tcimeplugin.h
SOURCES += \
tcinputmethod.cpp \
tcimeplugin.cpp
OTHER_FILES += \
tcime.json
include(../../../config.pri)
LAYOUT_FILES += \
$$LAYOUTS_BASE/content/layouts/zh_TW/dialpad.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/digits.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/main.qml \
$$LAYOUTS_BASE/content/layouts/zh_TW/numbers.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/symbols.qml
layouts.files = $$LAYOUT_FILES
layouts.base = $$LAYOUTS_BASE
layouts.prefix = $$LAYOUTS_PREFIX
RESOURCES += layouts
cangjie: DEFINES += HAVE_TCIME_CANGJIE
zhuyin: DEFINES += HAVE_TCIME_ZHUYIN
QMAKE_USE += tcime
!no-bundle-tcime {
TCIME_FILES += ../3rdparty/tcime/data/qt/dict_phrases.dat
cangjie: TCIME_FILES += \
../3rdparty/tcime/data/qt/dict_cangjie.dat
zhuyin: TCIME_FILES += \
../3rdparty/tcime/data/qt/dict_zhuyin.dat
tcime.files = $$TCIME_FILES
tcime.base = $$PWD/..
tcime.prefix = /QtQuick/VirtualKeyboard
RESOURCES += tcime
} else {
tcime_data.files = \
$$PWD/../3rdparty/tcime/data/qt/dict_phrases.dat
cangjie: tcime_data.files += \
$$PWD/../3rdparty/tcime/data/qt/dict_cangjie.dat
zhuyin: tcime_data.files += \
$$PWD/../3rdparty/tcime/data/qt/dict_zhuyin.dat
tcime_data.path = $$VIRTUALKEYBOARD_INSTALL_DATA/tcime
INSTALLS += tcime_data
!prefix_build: COPIES += tcime_data
}
win32 {
QMAKE_TARGET_PRODUCT = "Qt Virtual Keyboard TCIME (Qt $$QT_VERSION)"
QMAKE_TARGET_DESCRIPTION = "Virtual Keyboard Extension for Qt."
}
PLUGIN_TYPE = virtualkeyboard
PLUGIN_CLASS_NAME = TCImePlugin
load(qt_plugin)
|
