Example compositor for the ivi application extension

A compositor with two areas, clients are maximized on one of those areas
depending on their ivi surface id.

Change-Id: I2dbb20b47e38680e14465d3a4a8147d64817de63
Reviewed-by: Paul Olav Tvete <paul.tvete@qt.io>

1 files changed, 97 insertions, 0 deletions

diff --git a/examples/wayland/ivi-compositor/main.qml b/examples/wayland/ivi-compositor/main.qml
new file mode 100644
index 000000000..6535296b6
--- /dev/null
+++ b/examples/wayland/ivi-compositor/main.qml
@@ -0,0 +1,97 @@
+/****************************************************************************
+**
+** Copyright (C) 2016 The Qt Company Ltd.
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.0
+import QtWayland.Compositor 1.0
+import QtQuick.Window 2.2
+
+WaylandCompositor {
+    id: wlcompositor
+    WaylandOutput {
+        compositor: wlcompositor
+        sizeFollowsWindow: true
+        window: Window {
+            width: 1024
+            height: 768
+            visible: true
+            Rectangle {
+                id: leftArea
+                width: parent.width / 2
+                height: parent.height
+                anchors.left: parent.left
+                color: "cornflowerblue"
+                Text {
+                    anchors.centerIn: parent
+                    text: "Ivi surface with id 1337"
+                }
+            }
+            Rectangle {
+                id: rightArea
+                width: parent.width / 2
+                height: parent.height
+                anchors.right: parent.right
+                color: "burlywood"
+                Text {
+                    anchors.centerIn: parent
+                    text: "Other surfaces"
+                }
+            }
+        }
+    }
+    Component {
+        id: chromeComponent
+        ShellSurfaceItem {
+            anchors.fill: parent
+            onSurfaceDestroyed: destroy()
+            onWidthChanged: handleResized()
+            onHeightChanged: handleResized()
+            function handleResized() {
+                shellSurface.sendConfigure(Qt.size(width, height));
+            }
+        }
+    }
+    IviApplication {
+        onIviSurfaceCreated: {
+            var surfaceArea = iviSurface.iviId === 1337 ? leftArea : rightArea;
+            var item = chromeComponent.createObject(surfaceArea, { "shellSurface": iviSurface } );
+            item.handleResized();
+        }
+    }
+}