1 files changed, 32 insertions, 0 deletions
diff --git a/src/compositor/compositor.pri b/src/compositor/compositor.pri
new file mode 100644
index 000000000..de95dc4ce
--- /dev/null
+++ b/src/compositor/compositor.pri
@@ -0,0 +1,32 @@
+CONFIG += module
+MODULE_PRI += $$PWD/../../modules/qt_compositor.pri
+
+INCLUDEPATH += $$PWD
+DEFINES += QT_WAYLAND_WINDOWMANAGER_SUPPORT
+DEFINES += QT_BUILD_COMPOSITOR_LIB
+
+!mac:use_pkgconfig {
+    CONFIG += link_pkgconfig
+    PKGCONFIG += wayland-server
+
+    #set the rpath
+    !isEmpty(QMAKE_LFLAGS_RPATH) {
+        WAYLAND_NEEDS_RPATH = $$system(pkg-config --libs-only-L wayland-server)
+        !isEmpty(WAYLAND_NEEDS_RPATH) {
+            WAYLAND_LIBDIR = $$system(pkg-config --variable=libdir wayland-server)
+            !isEmpty(WAYLAND_LIBDIR):QMAKE_LFLAGS += $${QMAKE_LFLAGS_RPATH}$${WAYLAND_LIBDIR}
+        }
+    }
+} else {
+    INCLUDEPATH += $$PWD/../3rdparty/wayland
+    LIBS += -L$$PWD/../../lib
+    LIBS += -lwayland-server -lffi
+}
+
+HEADERS += qtcompositorversion.h
+
+include ($$PWD/util/util.pri)
+include ($$PWD/wayland_wrapper/wayland_wrapper.pri)
+include ($$PWD/hardware_integration/hardware_integration.pri)
+include ($$PWD/compositor_api/compositor_api.pri)
+include ($$PWD/windowmanagerprotocol/windowmanagerprotocol.pri)