summaryrefslogtreecommitdiffstats
path: root/qtwayland.pro
blob: b5088072f828308397050737a6ed2f23f8af5177 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
requires(linux:!android)

load(configure)
qtCompileTest(wayland)
qtCompileTest(xkbcommon)
qtCompileTest(wayland_cursor)
qtCompileTest(wayland_scanner)
qtCompileTest(wayland_egl)
qtCompileTest(brcm_egl)
qtCompileTest(glx)
qtCompileTest(xcomposite)
qtCompileTest(drm_egl_server)
qtCompileTest(libhybris_egl_server)

load(qt_parts)

!config_wayland {
    warning("QtWayland requires Wayland 1.4.0 or higher, QtWayland will not be built")
    SUBDIRS =
}

!config_xkbcommon {
    warning("No xkbcommon 0.2.0 or higher found, disabling support for it")
}

!config_wayland_scanner {
    warning("QtWayland requires wayland-scanner, QtWayland will not be built")
    SUBDIRS =
}

!config_wayland_cursor {
    warning("QtWayland requires wayland-cursor, QtWayland will not be built")
    SUBDIRS =
}

!config_wayland_egl {
    message("no wayland-egl support detected, cross-toolkit compatibility disabled");
}