blob: de95dc4ce79588b89685ff039f8c9b0d42bead4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
CONFIG += module
MODULE_PRI += $$PWD/../../modules/qt_compositor.pri
INCLUDEPATH += $$PWD
DEFINES += QT_WAYLAND_WINDOWMANAGER_SUPPORT
DEFINES += QT_BUILD_COMPOSITOR_LIB
!mac:use_pkgconfig {
CONFIG += link_pkgconfig
PKGCONFIG += wayland-server
#set the rpath
!isEmpty(QMAKE_LFLAGS_RPATH) {
WAYLAND_NEEDS_RPATH = $$system(pkg-config --libs-only-L wayland-server)
!isEmpty(WAYLAND_NEEDS_RPATH) {
WAYLAND_LIBDIR = $$system(pkg-config --variable=libdir wayland-server)
!isEmpty(WAYLAND_LIBDIR):QMAKE_LFLAGS += $${QMAKE_LFLAGS_RPATH}$${WAYLAND_LIBDIR}
}
}
} else {
INCLUDEPATH += $$PWD/../3rdparty/wayland
LIBS += -L$$PWD/../../lib
LIBS += -lwayland-server -lffi
}
HEADERS += qtcompositorversion.h
include ($$PWD/util/util.pri)
include ($$PWD/wayland_wrapper/wayland_wrapper.pri)
include ($$PWD/hardware_integration/hardware_integration.pri)
include ($$PWD/compositor_api/compositor_api.pri)
include ($$PWD/windowmanagerprotocol/windowmanagerprotocol.pri)
|