1 files changed, 0 insertions, 68 deletions
diff --git a/src/core/gn_run.pro b/src/core/gn_run.pro
deleted file mode 100644
index 4688ea59d..000000000
--- a/src/core/gn_run.pro
+++ /dev/null
@@ -1,68 +0,0 @@
-include($$QTWEBENGINE_OUT_ROOT/src/buildtools/qtbuildtools-config.pri)
-include($$QTWEBENGINE_OUT_ROOT/src/core/qtwebenginecore-config.pri)
-QT_FOR_CONFIG += buildtools-private webenginecore-private core-private gui-private
-
-TEMPLATE = aux
-
-qtConfig(debug_and_release): CONFIG += debug_and_release
-qtConfig(build_all): CONFIG += build_all
-
-QT_TOOL.ninja.binary = $$shell_quote($$shell_path($$ninjaPath()))
-
-win32 {
-    # Add the gnuwin32/bin subdir of qt5.git to PATH. Needed for calling bison and friends.
-    gnuwin32path.name = PATH
-    gnuwin32path.value = $$shell_path($$clean_path($$QTWEBENGINE_ROOT/../gnuwin32/bin))
-    gnuwin32path.CONFIG += prepend
-    exists($$gnuwin32path.value): QT_TOOL_ENV = gnuwin32path
-}
-
-qtPrepareTool(NINJA, ninja)
-QT_TOOL_ENV =
-
-build_pass|!debug_and_release {
-    gn_binary = gn
-
-    runninja.target = run_ninja
-
-    gn_args = $$gnWebEngineArgs()
-
-    gn_args += "qtwebengine_target=\"$$system_path($$OUT_PWD/$$getConfigDir()):QtWebEngineCore\""
-
-    !qtConfig(webengine-system-gn) {
-        gn_binary = $$system_quote($$system_path($$gnPath()))
-    }
-
-    gn_args = $$system_quote($$gn_args)
-    gn_src_root = $$system_quote($$system_path($$QTWEBENGINE_ROOT/$$getChromiumSrcDir()))
-    gn_build_root = $$system_quote($$system_path($$OUT_PWD/$$getConfigDir()))
-    gn_python = "--script-executable=$$pythonPathForSystem()"
-    gn_run = $$gn_binary gen $$gn_build_root $$gn_python --args=$$gn_args --root=$$gn_src_root
-
-    message("Running: $$gn_run ")
-    !system($$gn_run) {
-        error("GN run error!")
-    }
-
-    ninjaflags = $$(NINJAFLAGS)
-    isEmpty(ninjaflags):!silent: ninjaflags = "-v"
-
-    runninja.commands = $$NINJA $$ninjaflags \$\(NINJAJOBS\) -C $$gn_build_root QtWebEngineCore
-    QMAKE_EXTRA_TARGETS += runninja
-
-    build_pass:build_all: default_target.target = all
-    else: default_target.target = first
-    default_target.depends = runninja
-    QMAKE_EXTRA_TARGETS += default_target
-}
-
-!build_pass:debug_and_release {
-    # Special GNU make target for the meta Makefile that ensures that our debug and release Makefiles won't both run ninja in parallel.
-    notParallel.target = .NOTPARALLEL
-    QMAKE_EXTRA_TARGETS += notParallel
-}
-
-build_pass:CONFIG(debug, debug|release) {
-    TARGET = gn_run_debug
-}
-