src/buildtools/gn.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

TEMPLATE = aux
option(host_build)

!debug_and_release: CONFIG += release

include($$QTWEBENGINE_OUT_ROOT/src/core/qtwebenginecore-config.pri)
QT_FOR_CONFIG += webenginecore-private

build_pass|!debug_and_release {
    !qtConfig(webengine-system-gn): CONFIG(release, debug|release) {
        buildgn.target = build_gn
        out = $$gnPath()
        out_path = $$dirname(out)
        !qtConfig(webengine-system-ninja): ninja_path = $$ninjaPath()
        else: ninja_path="ninja"
        # check if it is not already build
        !exists($$out) {
            src_3rd_party_dir = $$absolute_path("$${getChromiumSrcDir()}/../", "$$QTWEBENGINE_ROOT")
            gn_bootstrap = $$system_path($$absolute_path(gn/build/gen.py, $$src_3rd_party_dir))

            gn_configure = $$system_quote($$gn_bootstrap) --no-last-commit-position --out-path $$out_path \
                           --cc \"$$which($$QMAKE_CC)\" --cxx \"$$which($$QMAKE_CXX)\" \
                           --ld \"$$which($$QMAKE_LINK)\"
            macos {
                gn_configure += --isysroot \"$$QMAKE_MAC_SDK_PATH\"
            }
            message($$gn_configure)
            !system("$$pythonPathForSystem() $$gn_configure") {
                error("GN generation error!")
            }
            !system("cd $$system_quote($$system_path($$out_path)) && $$ninja_path $$basename(out)" ) {
                error("GN build error!")
            }
        }
        QMAKE_DISTCLEAN += $$out
    }
}