blob: 5314d30d226b4e11f0983d2ee419eb59903dace4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
TARGET = QtPdf
MODULE = pdf
QT += gui core core-private
QT_PRIVATE += network
TEMPLATE = lib
CONFIG += c++11
CONFIG -= precompile_header # Not supported by upstream header files
INCLUDEPATH += $$QTWEBENGINE_ROOT/src/pdf
CHROMIUM_SRC_DIR = $$QTWEBENGINE_ROOT/$$getChromiumSrcDir()
CHROMIUM_GEN_DIR = $$OUT_PWD/../$$getConfigDir()/gen
INCLUDEPATH += $$QTWEBENGINE_ROOT/src/pdf \
$$CHROMIUM_GEN_DIR \
$$CHROMIUM_SRC_DIR \
api
DEFINES += QT_BUILD_PDF_LIB
win32: DEFINES += NOMINMAX
linking_pri = $$OUT_PWD/$$getConfigDir()/$${TARGET}.pri
!include($$linking_pri) {
error("Could not find the linking information that gn should have generated.")
}
isEmpty(NINJA_OBJECTS): error("Missing object files from QtPdf linking pri.")
isEmpty(NINJA_LFLAGS): error("Missing linker flags from QtPdf linking pri")
isEmpty(NINJA_ARCHIVES): error("Missing archive files from QtPdf linking pri")
isEmpty(NINJA_LIBS): error("Missing library files from QtPdf linking pri")
NINJA_OBJECTS = $$eval($$list($$NINJA_OBJECTS))
RSP_FILE = $$OUT_PWD/$$getConfigDir()/$${TARGET}.rsp
for(object, NINJA_OBJECTS): RSP_CONTENT += $$object
write_file($$RSP_FILE, RSP_CONTENT)
macos:LIBS_PRIVATE += -Wl,-filelist,$$shell_quote($$RSP_FILE)
linux:LIBS_PRIVATE += @$$RSP_FILE
# QTBUG-58710 add main rsp file on windows
win32:QMAKE_LFLAGS += @$$RSP_FILE
linux: LIBS_PRIVATE += -Wl,--start-group $$NINJA_ARCHIVES -Wl,--end-group
else: LIBS_PRIVATE += $$NINJA_ARCHIVES
LIBS_PRIVATE += $$NINJA_LIB_DIRS $$NINJA_LIBS
QMAKE_DOCS = $$PWD/doc/qtpdf.qdocconf
gcc {
QMAKE_CXXFLAGS_WARN_ON += -Wno-unused-parameter
}
msvc {
QMAKE_CXXFLAGS_WARN_ON += -wd"4100"
}
ios: OBJECTS += $$NINJA_OBJECTS
SOURCES += \
qpdfbookmarkmodel.cpp \
qpdfdocument.cpp \
qpdfpagenavigation.cpp \
qpdfpagerenderer.cpp
# all "public" headers must be in "api" for sync script and to hide auto generated headers
# by Chromium in case of in-source build
HEADERS += \
api/qpdfbookmarkmodel.h \
api/qpdfdocument.h \
api/qpdfdocument_p.h \
api/qpdfdocumentrenderoptions.h \
api/qpdfnamespace.h \
api/qpdfpagenavigation.h \
api/qpdfpagerenderer.h \
api/qtpdfglobal.h \
api/qpdfdocument_p.h
load(qt_module)
|
