summaryrefslogtreecommitdiffstats
path: root/src/src.pro
blob: bc01515369ce9981c9ea58ce629314c05896adbc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
TEMPLATE = subdirs

# The first three subdirs contain dummy .pro files that are used by qmake
# to generate a corresponding .gyp file

# Phony pro file that extracts things like compiler and linker from qmake
qmake_extras.subdir = build/qmake_extras

# Phony pro files that generate gyp files. Will be built by ninja.
lib.depends = qmake_extras

# API libraries
webengine_lib.subdir = lib/quick
webengine_lib.target = sub-webengine-lib
webengine_lib.depends = build
quick_plugin_lib.subdir = lib/quick/plugin
quick_plugin_lib.target = sub-quick-plugin-lib
quick_plugin_lib.depends = webengine_lib
quick_experimental_plugin_lib.subdir = lib/quick/plugin/experimental
quick_experimental_plugin_lib.target = sub-quick-experimental-plugin-lib
quick_experimental_plugin_lib.depends = webengine_lib
widgets_lib.subdir = lib/widgets
widgets_lib.target = sub-widgets-lib
widgets_lib.depends = build

process.depends = build
sub_examples.depends = quick_plugin_lib quick_experimental_plugin_lib
sub_tests.depends = quick_plugin_lib quick_experimental_plugin_lib

# This is where we use the generated gypi files and run gyp_qtwebengine
build.depends = resources lib

SUBDIRS += qmake_extras \
          resources \
          lib \
          process \
          build \
          webengine_lib \
          quick_plugin_lib \
          quick_experimental_plugin_lib

qtHaveModule(widgets) {
    SUBDIRS += widgets_lib
    sub_examples.depends += widgets_lib
    sub_tests.depends += widgets_lib
}

# Ninja executable location needs to be determined early for extra targets. Should be fetched from cache most of the time anyway.
NINJA_EXECUTABLE = $$findOrBuildNinja()

# Extra targets that invoke ninja on the desired configuration added for convenience
release.target = release
release.commands = $$NINJA_EXECUTABLE -C $$getOutDir()/Release
release.depends: qmake

debug.target = debug
debug.commands = $$NINJA_EXECUTABLE -C $$getOutDir()/Debug
debug.depends: qmake

QMAKE_EXTRA_TARGETS += release \
                       debug

# Move this to the beginning of the project file as soon as we moved to the src layout
load(qt_parts)