Add deployqt target

deployqt target provides a way to deploy all Qt dependencies of
studio and viewer executables utilizing windeployqt and macdeployqt
tools.

Task-number: QT3DS-1057
Change-Id: I98087558ec7c37aaa43f84f6d93ca84fcb01868d
Reviewed-by: Antti Määttä <antti.maatta@qt.io>
Reviewed-by: Tomi Korpipää <tomi.korpipaa@qt.io>

1 files changed, 27 insertions, 0 deletions

diff --git a/qt3dstudio.pro b/qt3dstudio.pro
index ea78bec6..4d520057 100644
--- a/qt3dstudio.pro
+++ b/qt3dstudio.pro
@@ -14,3 +14,30 @@ SUBDIRS += \
     doc
 
 load(qt_parts)
+
+# 'deployqt' target can be used to automatically copy necessary Qt libraries needed by studio
+# applications. DEPLOY_DIR environment variable must point to the directory where
+# Qt3DStudio and Qt3DViewer executables/application bundles are found.
+# The required Qt libraries are copied into that directory/bundles.
+!build_pass|!debug_and_release {
+    macos|win32 {
+        macos {
+            deploytool = macdeployqt
+            exesuffix = .app
+        } else:win32 {
+            deploytool = windeployqt
+            exesuffix = .exe
+        }
+
+        qtPrepareTool(DEPLOY_TOOL, $$deploytool)
+
+        install_dir =
+        deployTarget.target = deployqt
+        deployTarget.commands = \
+            $$DEPLOY_TOOL $$shell_quote(\$(DEPLOY_DIR)/Qt3DStudio$${exesuffix}) \
+                -qmldir=$$shell_quote($$PWD/src/Authoring/Studio/Palettes) && \
+            $$DEPLOY_TOOL $$shell_quote(\$(DEPLOY_DIR)/Qt3DViewer$${exesuffix}) \
+                -qmldir=$$shell_quote($$PWD/src/Viewer/Qt3DViewer)
+        QMAKE_EXTRA_TARGETS += deployTarget
+    }
+}