Partial Revert of "qtwebkit: Fix build with ruby 3.2+"

This partially reverts commit a083cdfdfa6a5860b846b80105fbfbf82f9ddd4c.

Fixes https://github.com/meta-qt5/meta-qt5/issues/503 for kirkstone
branch where sip3 still existed in meta-oe, for meta-qt5/master someone
would need to replace sip3 or otherwise resolve:
https://git.openembedded.org/meta-openembedded/commit/?id=4dc1c6e16b31d30aca05c52fa0209c74eedd6842

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

2 files changed, 69 insertions, 2 deletions

diff --git a/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb b/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb
new file mode 100644
index 00000000..b751268d
--- /dev/null
+++ b/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb
@@ -0,0 +1,67 @@
+SUMMARY = "Python Qt5 Bindings"
+AUTHOR = "Phil Thomson @ riverbank.co.uk"
+HOMEPAGE = "https://www.riverbankcomputing.com/software/pyqt"
+SECTION = "devel/python"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE;md5=d32239bcb673463ab874e80d47fae504 \
+"
+
+inherit pypi
+
+PYPI_PACKAGE = "PyQt5"
+
+SRC_URI[md5sum] = "b60f895e70d31d774e6cd374efd17c65"
+SRC_URI[sha256sum] = "d9a76b850246d08da9863189ecb98f6c2aa9b4d97a3e85e29330a264aed0f9a1"
+
+S = "${WORKDIR}/PyQt5-${PV}"
+
+inherit qmake5
+inherit python3native python3-dir
+
+DEPENDS = "qtbase qtdeclarative qtquickcontrols2"
+DEPENDS += "sip3 sip3-native python3"
+
+export BUILD_SYS
+export HOST_SYS
+export STAGING_INCDIR
+export STAGING_LIBDIR
+
+PARALLEL_MAKEINST = ""
+
+DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)}"
+
+PYQT_MODULES = "QtCore QtGui QtNetwork QtXml QtNetwork QtQml ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'QtQuick QtWidgets QtQuickWidgets', '', d)}"
+
+do_configure:prepend() {
+    cd ${S}
+    echo "py_platform = linux" > pyqt.cfg
+    echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)${PYTHON_ABI}" >> pyqt.cfg
+    echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "py_pylib_lib = python$%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
+    echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
+    echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
+    echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
+    echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
+    echo "qt_shared = True" >> pyqt.cfg
+    QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
+    echo "[Qt $QT_VERSION]" >> pyqt.cfg
+    echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
+    echo yes | ${PYTHON} configure.py --verbose --qmake  ${STAGING_BINDIR_NATIVE}/${QT_DIR_NAME}/qmake --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
+}
+
+do_compile() {
+    cd ${S}
+    oe_runmake
+}
+
+do_install() {
+    cd ${S}
+    oe_runmake MAKEFLAGS='-j 1' install
+}
+
+FILES:${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt5/"
+
+RDEPENDS:${PN} = "qtbase qtdeclarative qtquickcontrols2 qtquickcontrols2-mkspecs"
+RDEPENDS:${PN} += "python3-core python3-sip3"
diff --git a/recipes-python/pyqtchart/python3-pyqtchart_5.15.1.bb b/recipes-python/pyqtchart/python3-pyqtchart_5.15.1.bb
index 0bb84fe0..03497034 100644
--- a/recipes-python/pyqtchart/python3-pyqtchart_5.15.1.bb
+++ b/recipes-python/pyqtchart/python3-pyqtchart_5.15.1.bb
@@ -20,7 +20,7 @@ inherit qmake5
 inherit python3native python3-dir
 
 DEPENDS = "qtcharts"
-DEPENDS += "sip sip-native python3 python3-pyqt5"
+DEPENDS += "sip3 sip3-native python3 python3-pyqt5"
 
 export BUILD_SYS
 export HOST_SYS
@@ -66,4 +66,4 @@ do_install() {
 FILES:${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/"
 
 RDEPENDS:${PN} = "qtbase qtdeclarative qtquickcontrols2 qtquickcontrols2-mkspecs qtcharts"
-RDEPENDS:${PN} += "python3-core sip python3-pyqt5"
+RDEPENDS:${PN} += "python3-core python3-sip3 python3-pyqt5"